Kopiëren door dubbelklik

[Stukke]

Dag experts

Volgend probleem doet zich voor...

Ik zou graag:
de gegevens van kolom B (vanaf B2 tot B400 ofzo) in Blad 1 kopiëren naar B10 in Blad 2 d.m.v. een dubbelklik.
de gegevens van kolom C (vanaf C2 tot C400 ofzo) in Blad 1 kopiëren naar B11 in Blad 2 d.m.v. een dubbelklik.

Blad 1 zijn deelnemers + gegevens.
Blad 2 is een soort van goedkeuringsformulier.

Alvast bedankt voor de moeite,

Tim

 

[Timshel]

Als ik het goed begrijp wil je een bereik op blad 1 van +/- 400 cellen kopieren naar 1 cel op blad 2.
Hoe ziet dat eruit?

 

[OctaFish]

Ik heb je gegevens uiteraard niet, en je geeft ook niet aan waar je precies wilt dubbelklikken, maar stoei hier maar eens mee:

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    Cells(1).CurrentRegion.Copy
    Sheets.Add After:=Sheets(Sheets.Count)
    ActiveSheet.Paste
    Sheets(1).Select
    Application.CutCopyMode = False
End Sub

 

[Stukke]

Moest het mogelijk zijn zou ik graag op de te kopiëren cellen dubbelklikken (bv. B25 en C25).
Dit zou respectievelijk in B10 en B11 op blad 2 verschijnen.

 

[Stukke]

Als ik het goed begrijp wil je een bereik op blad 1 van +/- 400 cellen kopieren naar 1 cel op blad 2.
Hoe ziet dat eruit?

1 cel uit het gehele bereik kopiëren is het doel

 

[Timshel]

Zoiets?

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    If Intersect(Target, Columns(2).Resize(, 2)) Is Nothing Then Exit Sub
    Cancel = True
    Sheets("Blad2").Range("B10").Offset(Target.Column - 2) = Target.Value
End Sub

 

[wieter]

Misschien bedoel je dit?
Dubbelklik = copy
Oeps, Tim was mij voor

 

[Stukke]

Super...
Timshel kwam met de gevraagde code :thumb:

Nu doet er zich een volgend iets voor...
De volgende code gebruikt ik al:
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Not Intersect(Target, Range("E2:E500")) Is Nothing Then
Target.Value = Date
End If

Hoe combineer ik deze twee?
End Sub

 

[Timshel]

Je kunt eenvoudig de actuele datum invoegen met de toetsencombi CTRL + ;.
Als het per se met dubbelklik moet:

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    If Not Intersect(Target, Range("E2:E500")) Is Nothing Then
        Target.Value = Date
        Exit Sub
    End If
    If Intersect(Target, Columns(2).Resize(, 2)) Is Nothing Then Exit Sub
    Cancel = True
    Sheets("Blad2").Range("B10").Offset(Target.Column - 2) = Target.Value
End Sub

 

[Stukke]

Bedankt Timshel... je bent een machine :thumb:

Ik zou nu nog graag dmv een dubbelklik op een cel in Kolom E de gegevens hiervan kopiëren naar cel E10 op blad 2.

Ik heb zelf wat geprobeerd... maar het lukt me jammer genoeg niet

 

[Timshel]

Moet bij een dubbelklik in kolom E dan ook nog de datum worden ingevoegd?

 

[Stukke]

Nee... in kolom E heb ik via gegevensvalidatie een keuzelijst aangemaakt. Eerst een keuze maken en dan via dubbelklik kopiëren naar Blad 2 E10

 

[Stukke]

Of is dit niet mogelijk?
Voorlopig heb ik deze code en ik wil dus graag hieraan toevoegen wat in bovenstaande post staat. Ik weet niet of dit mogelijk is, omwille van de gegevensvalidatie in die cellen??

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    If Not Intersect(Target, Range("E2:E500")) Is Nothing Then
        Target.Value = Date
        Exit Sub
    End If
    If Not Intersect(Target, Range("A2:A500")) Is Nothing Then
        Target.Value = Date
        Exit Sub
    End If
    If Intersect(Target, Columns(2).Resize(, 2)) Is Nothing Then Exit Sub
    Cancel = True
    Sheets("F141").Range("B10").Offset(Target.Column - 2) = Target.Value
End Sub

 

[Timshel]

Ik kan mij moeilijk een voorstelling maken van kolom E in je werkblad.
Eerst wil je met dubbelklik een actuele datum invoegen, nu staat er kennelijk gegevensvalidatie in die kolom en moet dubbelklik de celinhoud kopiëren naar het andere werkblad.
Wat is het nou?

 

[Stukke]

oei, ik heb een fout gemaakt...

Kolom A / Kolom E: dubbelklik = datum
Kolom B / Kolom C: dubbelklik = copy naar blad 2
Kolom F: eerste keuze maken dmv gegevensvalidatie, nadien dubbelklik = copy naar blad 2

Het moet dus kolom F zijn en niet E, mijn excuses

 

[Timshel]

Probeer het zo:

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    If Intersect(Target, Range("A2:C500,E2:F500")) Is Nothing Then Exit Sub
    Cancel = True
    Select Case Target.Column
        Case 1, 5
            Target = Date
        Case 2, 3
            Sheets("F141").Range("B10").Offset(Target.Column - 2) = Target.Value
        Case 6
            Sheets("F141").Range("E10") = Target.Value
    End Select
End Sub

 

[Stukke]

ONGELOOFLIJK!!!

:thumb:
werkt perfect

Bedankt!