Nieuwe uitdaging... getal laten zien welke ik mist.

[Gerton64]

Heb een (jaar) rooster daar in worden nummers aan een persoon gegeven (brandweer). perdag word er een nummer gegeven aan een persoon. Nu heb ik een formule erin staan dat je kan zien of die dag je een nummer mist. door middel van een uitroepteken.

De nummers die uitgedeeld worden zijn = Bev,1,2,3,4,9

=ALS(EN(AANTAL.ALS(HS52:HS69;"bev")=1;AANTAL.ALS(HS52:HS69;9)=1;AANTAL.ALS(HS52:HS69;1)=1;AANTAL.ALS(HS52:HS69;2)=1;AANTAL.ALS(HS52:HS69;3)=1;AANTAL.ALS(HS52:HS69;4)=1);"ok";"!")

Vraag:
Zou het mogelijk kunnen wezen om, als je 1 nummer mist het nummer te laten zien ipv het uitroepteken, en als er meer nummers zou missen dan de uitroepteken.

Groet Gerton

 

[AlexCEL]

Zou het mogelijk kunnen wezen om, als je 1 nummer mist het nummer te laten zien ipv het uitroepteken, en als er meer nummers zou missen dan de uitroepteken.

Ik heb gezocht naar een elegantere oplossing om exact dit te doen, maar kom op dit moment niet verder dan dit:

=ALS(SOM(ALS(AANTAL.ALS(HS52:HS69;{1;2;3;4;9;"Bev"})=1;1;0))<5;"!";KIEZEN(ALS(AANTAL.ALS(HS52:HS69;1)<>1;1;ALS(AANTAL.ALS(HS52:HS69;2)<>1;2;ALS(AANTAL.ALS(HS52:HS69;3)<>1;3;ALS(AANTAL.ALS(HS52:HS69;4)<>1;4;ALS(AANTAL.ALS(HS52:HS69;9)<>1;5;ALS(AANTAL.ALS(HS52:HS69;"Bev")<>1;6;7))))));1;2;3;4;9;"Bev";"ok"))

Nog een ietsje korter alternatief (Matrix-formule, dus na invoeren afsluiten met Control+Shift+Enter)

=ALS(SOM(ALS(AANTAL.ALS(HS52:HS69;{1;2;3;4;9;"Bev"})=1;1;0))<5;"!";KIEZEN(ALS.FOUT(VERGELIJKEN(999;ALS.FOUT(VIND.ALLES({"Bev";1;2;3;4;9};HS52&HS53&HS54&HS55&HS56&HS57&HS58&HS59&HS60&HS61&HS62&HS63&HS64&HS65&HS66&HS67&HS68&HS69);999);0);7);"Bev";1;2;3;4;9;"ok"))

 

[Gerton64]

Ik ga het morgen gelijk proberen. laat het weten.

 

[MarcelBeug]

In Excel 2016 kun je TEKST.COMBINEREN gebruiken. De volgende formule geeft de ontbrekende elementen, kommagescheiden.

=TEKST.COMBINEREN(",";1;ALS(ISNB(VERGELIJKEN({"Bev";1;2;3;4;9};HS52:HS69;0));{"Bev";1;2;3;4;9};""))

 

[Gerton64]

Heren heb er een voorbeeld bij gedaan, heb wel het bestand behoorlijk moeten toetakelen. hi
Vanaf kolom AJ16 worden de dagindeling ingedeeld (verticaal)
Ik heb de formules van Alex en Marcel erin gezet maar werk bij mij nog niet. krijg #NAAM?

Zie ik iets over het hoofd?


Bekijk bijlage Rooster 2017q3.xlsm

 

[VenA]

Als je met XL-2010 werkt dan moet je KIEZEN() aanpassen in KIES() dan werkt de formule van AlexCEL.

 

[AlexCEL]

De formule in AM33 werkt gewoon bij mij.
N.B.1: lees net de post van VenA hierboven, dit zou kunnen verklaren waarom het niet werkt. Eventueel aanpassen zoals voorgesteld.
N.B.2: volgens deze link: https://support.office.com/nl-nl/article/KIEZEN-functie-fc5c184f-cb62-4ec7-a46e-38653b98f5bc?ui=nl-NL&rs=nl-NL&ad=NL, zou KIEZEN moeten werken in excel 2010... (??)

De formule in AR33 heeft enkele aandachtspunten:
1. je hebt het bereik niet correct aangepast, er zit een kringverwijzing in (naar AR33 zelf)
2. de formule kijkt naar de waarde "Bev" zoals je gespecificeerd had in post #1. In je bestand gebruik je echter de afkorting "bev" (zonder hoofdletter). De formule, meer specifiek het VIND.ALLES gedeelte, is hoofdlettergevoelig.
3. de correcte formule wordt dus (let nogmaals op: dit is een matrix-formule, dus afsluiten met Control+Shift+Enter na invoeren/wijzigen):

=ALS(SOM(ALS(AANTAL.ALS([COLOR="#FF0000"]AR15:AR32[/COLOR];{1;2;3;4;9;"[COLOR="#FF0000"]b[/COLOR]ev"})=1;1;0))<5;"!";KIEZEN(ALS.FOUT(VERGELIJKEN(999;ALS.FOUT(VIND.ALLES({"[COLOR="#FF0000"]b[/COLOR]ev";1;2;3;4;9};AR15&AR16&AR17&AR18&AR19&AR20&AR21&AR22&AR23&AR24&AR25&AR26&AR27&AR28&AR29&AR30&AR31&AR32);999);0);7);"[COLOR="#FF0000"]b[/COLOR]ev";1;2;3;4;9;"ok"))

De formule in AX33 kan ik niet controleren, de functie is niet compatibel met mijn versie van Excel. En als je Excel 2010 gebruikt, ook niet met die van jou.

Hier alvast ingevuld: Bekijk bijlage Rooster 2017q3 (AC).xlsm

 

[Gerton64]

Dit is echt GAAF !!! wij hebben hiet trouwens Excel2010
Precies wat ik bedoel, heb de formule gebruikt van Alex

=ALS(SOM(ALS(AANTAL.ALS(AM15:AM32;{1;2;3;4;9;"Bev"})=1;1;0))<5;"!";KIES(ALS(AANTAL.ALS(AM15:AM32;1)<>1;1;ALS(AANTAL.ALS(AM15:AM32;2)<>1;2;ALS(AANTAL.ALS(AM15:AM32;3)<>1;3;ALS(AANTAL.ALS(AM15:AM32;4)<>1;4;ALS(AANTAL.ALS(AM15:AM32;9)<>1;5;ALS(AANTAL.ALS(AM15:AM32;"bev")<>1;6;7))))));1;2;3;4;9;"bev";"ok"))

De formule Laat zien wel nummer je mist, en vul je dubbele waardes in, geeft hij het ook aan.
Heren bedankt voor het meedenken, ga eerst proberen de formule te lezen Hmmm.

Nogmaals bedankt... mag een slotje op.

 

[AlexCEL]

Mooi. Je titel was correct gekozen, het was wel een uitdaging... maar dat vind ik leuk, daarvoor ben ik hier en ik heb ook weer zaken geleerd. :thumb:

Dat slotje is hier een groen vinkje en dat mag je zelf aanbrengen door rechts bovenaan de pagina de vraag op opgelost te zetten.

Succes er verder mee.

 

[Gerton64]

Top. Maar voor dat ik op groene vinkje klikt wil ik nog wel wat kwijt.

Complimenten aan de beheerders van de site, en vooral de Excel-mannen die steeds de tijd en energie in steken voor de wat mindere ervaren Excel gebruikers.

Groet Gerton
Un mindere ervaren Excel gebruiker.

 

[VenA]

N.B.2: volgens deze link: https://support.office.com/nl-nl/article/KIEZEN-functie-fc5c184f-cb62-4ec7-a46e-38653b98f5bc?ui=nl-NL&rs=nl-NL&ad=NL, zou KIEZEN moeten werken in excel 2010... (??)

De Nl versie van Xl-2010 heeft een nogal bijzonder bibliotheek van vertaalde functies, om er een paar te noemen:
- DEEL() is MIDDEN();
- ZOEKEN() is OPZOEKEN();
- KIEZEN() is KIES();
- etc.

Zelf gebruik ik meestal de En versie van Xl-2010 daar heb je dit probleem niet en de functies zijn meestal ook korter. bv SPATIES.WISSEN() vs TRIM(),VERGELIJKEN() vs MATCH():d

Dit soort dwalingen van MS onderstreept o.a het belang van jouw voettekst.

 

[Gerton64]

Ik heb toch nog een vraagje, er zit 1 fout in met invullen van nummer 1 deze word niet getoond als fout en ook als je 2x nummer 1 erinzet geeft hij heb niet als fout.

=ALS(SOM(ALS(AANTAL.ALS(AO52:AO70;{1;2;3;4;9;"Bev"})=1;1;0))<5;"!";KIES(ALS(AANTAL.ALS(AO52:AO70;1)<1;1;ALS(AANTAL.ALS(AO52:AO70;2)<>1;2;ALS(AANTAL.ALS(AO52:AO70;3)<>1;3;ALS(AANTAL.ALS(AO52:AO70;4)<>1;4;ALS(AANTAL.ALS(AO52:AO70;9)<>1;5;ALS(AANTAL.ALS(AO52:AO70;"bev")<>1;6;7))))));1;2;3;4;9;"bev";"o k"))

 

[Gerton64]

werkt weer....opgelost.