Aangeleverde draaitabeldata omzetten naar kolommen

[hvanbeek]

Beste helper,

Ik heb een vraag over Excel.
In de bijlage zie je in het 1e tabblad de aangeleverde data (dus zonder brongegevens).
Nu wil ik graag de locaties en aantallen ook in kolommen krijgen, zodat ik andere analyses kan doen met de geleverde data.
Zie 2e tabblad voor gewenste resultaat.

Wie kan mij helpen?

Hartelijke groet,


Hendrik van Beek.

 

[Timshel]

Voeg een werkblad "Uitvoer" toe en draai deze maco:

Sub tsh()
    Dim Br, BrUit
    Dim i As Long, j As Long, k As Long
    
    ReDim BrUit(Application.Count(Sheets(1).Cells(1).CurrentRegion.Offset(1, 3)), 4)
    Br = Sheets(1).Cells(1).CurrentRegion
    For i = 2 To UBound(Br)
        For j = 4 To UBound(Br, 2)
            If Br(i, j) <> "" Then
                BrUit(k, 0) = Br(i, 1)
                BrUit(k, 1) = Br(i, 2)
                BrUit(k, 2) = Br(i, 3)
                BrUit(k, 3) = Br(1, j)
                BrUit(k, 4) = Br(i, j)
                k = k + 1
            End If
        Next
    Next
    Sheets("Uitvoer").Cells(1).Resize(UBound(BrUit), 5) = BrUit
End Sub

 

[snb]

Sub M_snb()
  sn = Sheets("aangeleverde data").Cells(1).CurrentRegion
    
  With CreateObject("scripting.dictionary")
    For j = 2 To UBound(sn)
      For jj = 4 To UBound(sn, 2)
        If sn(j, jj) > 0 Then .Item(sn(j, 2) & sn(1, jj)) = Array(sn(j, 1), sn(j, 2), sn(j, 3), sn(1, jj), sn(j, jj))
      Next
    Next
    
    Sheets("gewenst resultaat").Cells(30, 1).Resize(.Count, 5) = Application.Index(.items, 0, 0)
       
  End With
End Sub

 

[hvanbeek]

bedankt voor jullie hulp!
Ik kan weer vooruit.

 

[pixcel]

Of zonder vba maar met Power Query:

let
    Source = Excel.CurrentWorkbook(){[Name="tableData"]}[Content],
    ChangedTypes = Table.TransformColumnTypes(Source,{{"Artikel", type text}, {"Art.nr.", Int64.Type}, {"Mutatie", type text}}),
    UnpivotedOtherColumns = Table.UnpivotOtherColumns(ChangedTypes, {"Artikel", "Art.nr.", "Mutatie"}, "Attribute", "Value")
in
    UnpivotedOtherColumns