{Aantal(als(b1:b100=a1...........

[kusje]

Een Matrixformule vraagje. Stel in Cel a1 staat Piet en in a2 staat Kees. In Kolom B staan de orders die ze (maar ook anderen)hebben gesloten. Dus Piet staat er bv 8 keer in en Kees 7 keer.
Kan ik dat ook in een Matrixformule wegschrijven en hoe? of dan toch beter DBAANTAL gebruiken.

 

[Finch]

Graag wat verdere verduidelijking (voorbeeldbestand?) want ik snap niets van je bedoeling.

 

[kusje]

OK, Hier een voorbeeld.

 

[Finch]

Ik weet nog steeds niet wat je wil bereiken. Verduidelijk dat eens.

 

[kusje]

Ik wil weten hoeveel Kees en Piet verkocht hebben. Als ik het alleen van Kees wil weten kan ik de gewone AANTAL.ALS wel gebruiken en dat kan ik ook bij Piet doen en deze optellen. Je kan het met de DBAANTAL functie oplossen, maar ik ben op zoek naar een Matrixformule oplossing

 

[Gert Bouwmeeste]

Kun je dat niet met een draaitabel oplossen?

 

[kusje]

Dus of de variabele in een matrixformule ook een lijstje kan zijn ipv 1 cel

 

[kusje]

Kun je dat niet met een draaitabel oplossen?

Kan ook, maar ik vroeg me gewoon af of het in een matrixformule kan.

 

[GiMe]

1)

=AANTAL.ALS(B2:B25;A2)

2)

=SOMPRODUCT((B2:B25=A2)*(B2:B25<>""))

3)

{=AANTAL(ALS(B2:B25=A2;--(B2:B25=A2)))}

4)

{=SOM(--(B2:B25=A2))}

3) & 4) Matrixformules !

en zo zijn er nog wel meer

 

[kusje]

Die begrijp ik, maar ik bedoel of de variabele ook A2:A3 kan zijn.

 

[kusje]

DBAANTAL werkt trouwens alleen met getallen, dus dat gaat niet op.

 

[tilpi]

Bedoel je zoiets??

=SOMPRODUCT((B2:B25=A2)+(B2:B25=A3))

Mvg

Piet

 

[kusje]

DBAANTALALC werkt wel. Maar nogmaals vraag ik me af of zoiets ook in een matrixformule kan worden weggeschreven

 

[kusje]

Bedoel je zoiets??

=SOMPRODUCT((B2:B25=A2)+(B2:B25=A3))

Mvg

Piet

Zou ook kunnen, maar dat is eigenlijk net zo iets als AANTAL.ALS een paar keer optellen. Stel dat ik een lijst met 50 namen heb in kolom A heb. dan zou ik dus bv willen:
{AANTAL(ALS(B2:B65536=A2:A50)} willen gebruiken, maar dat doet ie vooralsnog niet

 

[GiMe]

=SOMPRODUCT((TRANSPONEREN(A2:A3)=B2:B25)*(B2:B25<>""))

Matrixformule !

 

[kusje]

Helemaal perfect :thumb:

 

[kusje]

Ik heb hem trouwens iets vereenvoudigt

{=AANTAL(ALS((B2:B25=TRANSPONEREN(A2:A4)) ; ))}

 

[Wigi]

Ik heb hem trouwens iets vereenvoudigt


{=AANTAL(ALS((B2:B25=TRANSPONEREN(A2:A4)) ; ))}

=SOMPRODUCT((TRANSPONEREN(A2:A3)=B2:B25)*(B2:B25<>""))

Matrixformule !

En waarom niet gewoon:

=SOM(AANTAL.ALS(B2:B25;A2:A3))

als matrixformule.

Wigi

EDIT: "gewoon" is verkeerd uitgedrukt, want zo gewoon is dit niet

 

[kusje]

Die is ook leuk. Dat Matrixgebeuren is echt kicken Wigi.

 

[GiMe]

Als Bereik en Criterium haaks op mekaar staan :

=AANTAL(ALS((B2:B25=C2:E2);0))

Matrix-formule !