ABC waardering

[Peter B]

Volgens mij is de formule van VenA correct (als ik het goed begrijp) en heb ik hem zelfs iets korter gekregen ...

=IF(SUMPRODUCT((E4:P4>0)*1)=12;"A";IF(SUM(E4:G4)*SUM(H4:J4)*SUM(K4:M4)*SUM(N4:P4)>0;"B";"C"))

 

[AlexCEL]

@Hunuloeloe
Ok, ik zie het. In de formule wordt gechecked of er 4 periodes of meer zijn waarin producten zijn verkocht. Als je de eerste 3 cellen leegmaakt dan is het aantal periodes nog steeds >=4, en daarmee wordt de uitkomst B. Er wordt inderdaad niet gechecked of ELK kwartaal een verkoop heeft. Strikt officieel voldoet het dus niet aan de vraagstelling. Akkoord.

Oplossing: formule VenA gebruiken

 

[RonaldB92]

Yes, thanks allen! De formule van VenA werkt en met de ALS.FOUT formule krijg ik de ABC zoals ik het wil.

Nu ga ik kijken of nog wat met de XYZ kan.

 

[AlexCEL]

Nu ga ik kijken of nog wat met de XYZ kan.

Zo bijvoorbeeld? Wel even een echte datum maken van bereik E1 t/m S1 (jan-16, feb-16, etc.)

=ALS(B2>0;ALS(SOMPRODUCT(($E$1:$S$1>=ZELFDE.DAG(VANDAAG();-12))*E2:S2)>0;"Z";ALS(SOMPRODUCT(($E$1:$S$1>=ZELFDE.DAG(VANDAAG();-24))*E2:S2)>0;"X";"Y"));"geen voorraad")

X als het 1 jaar niet verkocht is, Y als het 2 jaar niet verkocht is en Z als het wel verkocht is recent. In alle gevallen moet er wel minstens 1 product op voorraad zijn.

Heb ik als volgt vertaald:
Afgelopen 365 dagen iets verkocht: Z
Tussen 1-2 jaar geleden: X
Langer dan 2 jaar geleden (of niets): Y

Minstens 1 product op voorraad voorwaarde snap ik niet zo goed. Zit wel in formule hierboven, maar wat moet gebeuren als er geen op voorraad is beschrijf je niet... (hierboven krijg je melding geen voorraad).

 

[RonaldB92]

Thanks, Alex. Dat is ook de manier, zoals ik bedoeld heb. Wat betreft de voorraad klopt het op deze manier. Als er geen voorraad is, dan maakt het niet uit of het wel of niet verkocht is. Oftewel deze melding is goed. Hartstikke bedankt, ik kan verder en heb weer wat geleerd!

 

[VenA]

@Peter B,
Is inderdaad slimmer met 0en en 1en omgaan :thumb:

Geheel zonder IF werkt volgens mij ook.

=CHAR(-(SUMPRODUCT((E2:P2>0)*1)=12)+(SUM(E2:G2)*SUM(H2:J2)*SUM(K2:M2)*SUM(N2:P2)=0)+66)

 

[RonaldB92]

Stel nu dat ik de grenzen van de formule wil aanpassen. Dus niet 1x per maand of 1x per kwartaal, maar 1x per half jaar bijvoorbeeld? Hoe pas ik de formule dan aan? Als ik de code zoals dit maak:

=ALS.FOUT(ALS(SOM(SOM(E2:J2)>0;SOM(K2:P2)>0;SOM(Q2:S2)>0;)=3;”A”;ALS(SOM(SOM(E18:G18)>0;SOM(H18:J18)>0;SOM(K18:M18)>0;SOM(N18:P18)>0;SOM(Q18:S18)>0)=5;"B";"C"));"Niet verkocht")

Dat werkt dus niet, hier probeer ik dat A 1x per half jaar is, B 1x per jaar is en C de rest.

=ALS.FOUT(ALS(SOM(E2:G2)*SOM(H2:J2)*SOM(K2:M2)*SOM(N2:P2)*SOM(Q2:S2)>0;"A";ALS(SOM(E2:J2)*SOM(K2:P2)*SOM(Q2:S2)>0;"B";"C"));"Niet verkocht")

Dit was het.

 

[Peter B]

Volgens mij kan dat dan op deze manier:

ENG: =IFERROR(IF(SUM(E2:J2)*SUM(K2:P2)>0;"A";IF(SUM(E2:P2)>0;"B";"C"));"Niet verkocht")
NL: =ALS.FOUT(ALS(SOM(E2:J2)*SOM(K2:P2)>0;"A";ALS(SOM(E2:P2)>0;"B";"C"));"Niet verkocht")

Let op. De opmerking "Niet verkocht" krijg je altijd als er een fout in de reeks zit, ook al wordt een product 10.000 keer per maand verkocht maar staat in één cel een ongeldige waarde (bv. =1/0)