Achetrgrond minimaliseren

[remmie63]

Achtergrond minimaliseren

Ik heb met veel hulp van dit forum (vooral Octafish) een goed werkende database op poten gezet. Ik heb een opstart werkscherm (formulier) hiervoor gemaakt met alle knoppen, tabs e.d. zodat er makkelijk en overzichtelijk aan gegevens kan worden gekomen.
Mijn laatste vraag is dan ook: is het mogelijk als de database wordt opgestart, dus het werkscherm verschijnt, dat de Access achtergrond geminimaliseerd wordt? Als ik nu de Access achtergrond minimaliseer, minimaliseert het werkscherm ook.
Bij voorbaat dank?

 

[OctaFish]

Dat kan alleen als je er een mde bestand van maakt. Op dat moment is je db een zelfstandig 'product' waar je ook niks meer aan kunt verbouwen.

 

[remmie63]

Wederom dank voor de info :thumb:. Ik heb wat informatie opgezocht over mde bestanden. Dan moet ik in ieder geval wel ervoor zorgen dat het geheel 100% vlekkeloos loopt. En natuurlijk een backup achter de hand houden om latere wijzigingen nog te kunnen aanbrengen. Het is, voor zover ik begrijp, dus niet mogelijk een mde bestand weer terug te convergeren naar een mdb bestand? Oftewel het is eenrichtingsverkeer!
Groet, Remco

 

[OctaFish]

Klopt. Het voordeel ervan is dan wel weer dat je gebruikers ook niks kunnen slopen

 

[remmie63]

Dat is inderdaad een groot voordeel.

 

[remmie63]

Beste Octafish,

ik heb een kopie van mij database omgezet naar een mde bestand. Echter de Access achtergrond blijft aanwezig. Wat doe ik verkeerd?

Groet, Remco

 

[OctaFish]

Je moet eigenlijk nog een functie (in een module) aan je db en een routine aan formulier toevoegen.
Dit is de functie:

Global Const SW_HIDE = 0
Global Const SW_SHOWNORMAL = 1
Global Const SW_SHOWMINIMIZED = 2
Global Const SW_SHOWMAXIMIZED = 3
Private Declare Function apiShowWindow Lib "user32" Alias "ShowWindow" (ByVal hwnd As Long, ByVal nCmdShow As Long) As Long

Function fSetAccessWindow(nCmdShow As Long)
'************ Code Start **********
' This code was originally written by Dev Ashish.
' It is not to be altered or distributed, except as part of an application.
' You are free to use it in any application, provided the copyright notice is left unchanged.
'
' Code Courtesy of Dev Ashish

'Usage Examples
'Maximize window:
' ?fSetAccessWindow(SW_SHOWMAXIMIZED)
'Minimize window:
' ?fSetAccessWindow(SW_SHOWMINIMIZED)
'Hide window:
' ?fSetAccessWindow(SW_HIDE)
'Normal window:
' ?fSetAccessWindow(SW_SHOWNORMAL)
'
Dim loX As Long
Dim loForm As Form
On Error Resume Next

    Set loForm = Screen.ActiveForm
    If Err <> 0 Then 'no Activeform
        If nCmdShow = SW_HIDE Then
            MsgBox "Cannot hide Access unless a form is on screen"
        Else
            loX = apiShowWindow(hWndAccessApp, nCmdShow)
            Err.Clear
        End If
    Else
        If nCmdShow = SW_SHOWMINIMIZED And loForm.Modal = True Then
            MsgBox "Cannot minimize Access with " _
            & (loForm.Caption + " ") _
            & "form on screen"
        ElseIf nCmdShow = SW_HIDE And loForm.PopUp <> True Then
            MsgBox "Cannot hide Access with " & (loForm.Caption + " ") & "form on screen"
        Else
            loX = apiShowWindow(hWndAccessApp, nCmdShow)
        End If
    End If
    fSetAccessWindow = (loX <> 0)

End Function

Op het formulier zet je deze code:

Private Sub Form_Open(Cancel As Integer)
    fSetAccessWindow (SW_SHOWMINIMIZED)
    DoCmd.RunCommand acCmdSizeToFitForm
End Sub

 

[Bakk4318]

Je kunt dit ook bereiken met een .mdb bestand. Bij de formulieren moet je dan wel de eigenschap "Pop-up" op ja zetten. Bij het laden van het formulier zet je dan de code:

DoCmd.RunCommand acCmdAppMinimize

Zorg er wel voor dat je de database afsluit bij het sluiten van het formulier:

DoCmd.Quit

Houdt er wel rekening mee, dat het niet zo goed beveiligd is als een mde bestand. Via de taakbalk kan Access worden geopend met een rechtermuisklik en de keuze "Vorig formaat". Je kunt natuurlijk wel de beveiliging toepassen die met elk mdb bestand kan.

Een voorbeeldje vind je in de bijlage.

 

[remmie63]

Heren, hartelijk dank ik ga ermee aan de slag!

Groet, Remco :thumb: