Alle schijven weergeven in een combobox

[Victorr99]

Beste Helpmijers,

Is het mogelijk om in een combobox alle schijven op de pc te laten zien?
Dus niet de schijfnaam, maar "C:\" (letter is bij iedere schijf dan uiteraard weer anders)

Ik heb al geexperimenteerd met de onderstaande code, maar kom er helaas niet verder mee.

Private Sub Userform_Initialize()

Dim SchijfNaam As String

SchijfNaam = Dir("Computer", vbDirectory) 

Do While SchijfNaam <> ""

    ComboBox1.AddItem SchijfNaam
    SchijfNaam = Dir

Loop


End Sub

 

[edmoor]

Daar kan je dit als basis voor gebruiken:

Sub ListAvailableDrives()
    Dim objDrv As Object
    Dim strMsg As String
 
    For Each objDrv In CreateObject("Scripting.FileSystemObject").Drives
        Select Case objDrv.DriveType
            Case 0: strMsg = strMsg & vbNewLine & objDrv.DriveLetter & ":\ Onbekend"
            Case 1: strMsg = strMsg & vbNewLine & objDrv.DriveLetter & ":\ Verwisselbare schijf"
            Case 2: strMsg = strMsg & vbNewLine & objDrv.DriveLetter & ":\ Standaard schijf"
            Case 3: strMsg = strMsg & vbNewLine & objDrv.DriveLetter & ":\ Netwerkt schijf"
            Case 4: strMsg = strMsg & vbNewLine & objDrv.DriveLetter & ":\ CD/DVD schijf"
            Case 5: strMsg = strMsg & vbNewLine & objDrv.DriveLetter & ":\ RAM schijf"
        End Select
    Next
 
    Set objDrv = Nothing
    MsgBox strMsg, vbInformation
End Sub

 

[HSV]

Of:

Sub GetHDletter()
Dim Drive As Object
With CreateObject("Scripting.FileSystemObject")
 For Each Drive In .Drives
    MsgBox .GetDrive(Drive)
 Next
End With
End Sub

 

[edmoor]

Yep. Da's hetzelfde

 

[HSV]

Ik wilde net reageren, en zag ineens jouw bericht staan, maar niet wetende wat.
Dus maar een korte tekst genomen; Of....

 

[edmoor]

Het gaat er maar om dat TS geholpen is

 

[Victorr99]

Bedankt allemaal, ik ben hier mee geholpen!

Mvg, Victor