Alle tabbladen opslaan behalve tabblad Settings

[N12047]

Het volgende:
Onderstaand stukje code gevonden met Google wat ik er goed kan gebruiken.

Ik zou graag elk tabblad van het werkboek afzonderlijk op willen slaan ZONDER het tabblad Settings.
Hoe krijg ik het voor elkaar dat hij tabblad Settings nu juist NIET opslaat?

Ben al bezig geweest met

.Visible,
.xlSheetVerryHidden,
For N = 1 To Sheets.Count - Sheets ("Settings")
If Sheet.Visible = true then

Maar tot op heden geen sucses.

Wie kan mij op weg helpen?

Sub SaveSheet()
    Dim Sheet As Worksheet, SheetName$, MyFilePath$, N&
    MyFilePath$ = ActiveWorkbook.Path & "\" & _
                  Left(ThisWorkbook.Name, Len(ThisWorkbook.Name) - 4)
    With Application
        On Error Resume Next
        MkDir MyFilePath
        For N = 1 To Sheets.Count
            Sheets(N).Activate
            SheetName = ActiveSheet.Name
            Cells.Copy
            Workbooks.Add (xlWBATWorksheet)
            With ActiveWorkbook
                With .ActiveSheet
                    .Paste
                    .Name = SheetName
                    [A1].Select
                End With
                .SaveAs Filename:=MyFilePath & "\" & SheetName & ".xlsx"
                .Close SaveChanges:=True
            End With
            .CutCopyMode = False
        Next
    End With
End Sub

 

[VenA]

Bv

Sub VenA()
  c00 = ActiveWorkbook.Path & "\" & Left(ThisWorkbook.Name, Len(ThisWorkbook.Name) - 4)
  If Dir(c00, 16) = "" Then MkDir c00
  For Each sh In Sheets
    If sh.Name <> "Settings" Then
      sh.Copy
      With ActiveWorkbook
        .SaveAs c00 & "\" & sh.Name & ".xlsx"
        .Close 0
      End With
    End If
  Next sh
End Sub

 

[popipipo]

Of het tabblad beveiligen tegen schrijven e.d.

 

[N12047]

Dank je wel VenA,

Het werkt uitmuntend.

Ik ga kijken wat het verschil is in de codes.

Opgelost!