Alleen het cijfer gedeelte uit een cell gebruiken in formule

[Allard]

Hey guys

Ik heb een aantal cellen met getallen erin..die ik bij elkaar wil optellen in een andere cell

Echter, de getallen worden voorafgegaan door een woord

tekst 0.002
tekst 0.211
andere tekst 22

Mijn vraag is.. hoe kan ik in mijn output cell deze getallen bij elkaar optellen (dus de woorden negeren?)

ps ik gebruik office 365
thanks!

 

[JEC.]

Kunnen r ook woorden achter het getal staan?

 

[Allard]

VOoralsnog staan de woorden ervoor (het is de naam van een crypto munt)...
Kan ook eventueel erachter, maar ik vermoed dat het makkelijker is om alles er voor te houden ?

 

[AlexCEL]

Zo wellicht?

=ZOEKEN(EXP(99);--LINKS(DEEL(SUBSTITUEREN(A1;".";",");MIN(VIND.ALLES({1;2;3;4;5;6;7;8;9;0};$A1&"1023456789"));999);RIJ(INDIRECT("1:999"))))

Met in A1 je eerste combinatie.

 

[Allard]

Sorry ik had moeten zeggen dat ik in de ENgelse versie zit.. veroorzaakt dat de foutmelding?

Formule heb ik in D14 gezet trouwens...B13 is het antwoord wat eruit zou moeten komen

 

[Senso]

=LOOKUP(EXP(99),--LEFT(MID(SUBSTITUTE(A1,".",","),MIN(FIND({1,2,3,4,5,6,7,8,9,0},$A1&"1023456789")),999),ROW(INDIRECT("1:999"))))

Met translator.

 

[JEC.]

Gebruik je komma of puntkomma binnen formules?

 

[JEC.]

Inene de som:

=SUM(--SUBSTITUTE(FILTERXML("<x><y>"&SUBSTITUTE(TEXTJOIN(" ";1;A1:A5);" ";"</y><y>")&"</y></x>";"//y[number()=.]");".";","))

Bovenstaande formule werkt ook als er tekst na de getallen staat.
Onderstaande formule kun je gebruiken wanneer de getallen altijd achteraan staan, misschien wat beter te begrijpen.

=SUMPRODUCT(--SUBSTITUTE(SUBSTITUTE(RIGHT(SUBSTITUTE(A1:A5;" ";REPT("@";100));100);"@";"");".";","))

Als je ook punten gebruikt ipv komma's moet je het maar even zeggen. Het kan dat de formules dan niet werken

 

[snb]

Vertel eens waarom je niet 1 kolom gebruikt om de soort munt aan te duiden en 1 kolom voor het aantal.
Heeft het werkblad te weinig kolommen in jouw geval ?

 

[Allard]

De reden is, dat als ik 2 kolommen gebruik, dan moet de breedte van de kolom boven de tekst breed genoeg blijven om te tekst te tonen.. En ik wil juist in het deel erboven een dunnere kolom houden (anders krijg ik daar veel loze ruimte)

En ik vind het ook leuk om te leren hoe het uberhaupt moet voor in de toekomst

 

[Allard]

Gebruik je komma of puntkomma binnen formules?

Ehm geen idee, waar kan ik dat zien? Volgens mij kommas

EDIT: ah dat is in te stellen in je WIndows Regio settings... daar staat de 'list seperator" op KOMMA

 

[JEC.]

Ik zou die even op puntkomma zetten. Dat zijn de instellingen die iedereen hier gebruikt. Daarom werkte de formule van Alex ook niet bij jou.

 

[Allard]

AH ja dat was het.. het werkt nu

Ik zal hem daar voortaan op zetten! thanks!

 

[JEC.]

Mooizo, welke formule heb je gekozen

 

[Allard]

de bovenste van de 2 die je noemde...