Alleen NIET lege cellen blokkeren/beveiligen

[jansm]

Hallo, is het mogelijk om (VBA) van een tabblad alleen de cellen met inhoud te blokkeren/beveiligen?

 

[jos1982]

Hoi Jansm,

Is dit voor jou een oplossing?

Sub beveiligen()

    Cells.Select
    Selection.Locked = False
    Selection.FormulaHidden = False


    Selection.SpecialCells(xlCellTypeConstants, 23).Select
    Selection.Locked = True
    Selection.FormulaHidden = False
    ActiveSheet.Protect DrawingObjects:=True, Contents:=True, Scenarios:=True
End Sub

Gr Jos

 

[jansm]

Jos, bedankt, dit werkt in principe. Zie voorbeeld bestand. Ik heb een knop beveiligen en een knop beveiliging opheffen. De code loopt vast als ik na het beveiligen een aantal onbeveiligde cellen invul en dan opnieuw beveilig. Op zich is het logisch dat je van het tabblad eerst de beveiliging opheft voordat nieuwe cellen invult. Maar is de code niet zodanig aan te passen dat dat niet nodig is? Ik ben er al blij mee hoor.
Bekijk bijlage TestBeveiligen.xlsb

 

[edmoor]

Begin de code van Jos eens met Activesheet.Unprotect

 

[jansm]

Goedemorgen Edmoor, YES. Jos en Edmoor bedankt

 

[jos1982]

Fijn om te horen dat het gelukt is! @edmoor, bedankt voor het aanvullen!

 

[HSV]

Stap af van 'select' en 'selection'.
Brei het dan eventueel aan elkaar met 'With'.

 

[jansm]

Dag HSV,
Ik heb With ActiveSheet ...... en End With geplaatst maar dan moet het nog aan elkaar gebreid worden. Kan jij breien? Ik kan alleen haken en punniken? Bekijk bijlage TestBeveiligen_2.xlsb

 

[jansm]

Harry,
ik kom niet verder dan de bijlage. Na de code JOS zijn alleen de cellen met inhoud geblokkeerd, dat is de bedoeling. Na code HSV zijn alle cellen geblokkeerd. Kan iemand de code _HSV aanpassen zodat ook hier alleen de cellen met inhoud zijn geblokkeerd.
Bekijk bijlage TestBeveiligen_3.xlsb

 

[HSV]

Lijkt me nou echt een mooi klusje voor @jos1982.
Steekt die er ook wat van op (daar was mijn vorig schrijven voor bedoeld).

 

[jos1982]

Lijkt me nou echt een mooi klusje voor @jos1982.
Steekt die er ook wat van op (daar was mijn vorig schrijven voor bedoeld).

Hoi Harry,

Bedankt voor de tip!

Ik leer daar inderdaad van. Alles wat ik weet van vba heb ik door middel van lezen en leren van anderen. Dus ik sta er altijd open voor om van jou en andere te leren!

Dit is dan waarschijnlijk de uitkomst waar Jansm naar op zoek is.

Sub beveiligen()

activesheet.Unprotect
With activesheet
    .Cells.SpecialCells(xlCellTypeVisible).Locked = False
    .Cells.SpecialCells(xlCellTypeConstants).Locked = True
End With
activesheet.Protect DrawingObjects:=True, Contents:=True, Scenarios:=True

End Sub

Groet Jos

 

[edmoor]

Dan maak je nog niet ten volle gebruik van de With opdracht:

Sub beveiligen()
    With ActiveSheet
        .Unprotect
        .Cells.SpecialCells(xlCellTypeVisible).Locked = False
        .Cells.SpecialCells(xlCellTypeConstants).Locked = True
        .Protect DrawingObjects:=True, Contents:=True, Scenarios:=True
    End With
End Sub

 

[jos1982]

Bedankt Edmoor!

Hopelijk wil je nog antwoord geven op een vraag:

Er zijn meerdere wegen die naar Rome leiden.. (Echter sommigen zijn beter)

Het feit dat je dit tussen de With en End With plaatst, heeft die alleen invloed op de snelheid van de uitvoering van de code?

(Ik hoop binnenkort wat tijd vrij te maken voor cursus..)

 

[edmoor]

Als voorbeeld de bovenstaande code zonder de With opdracht, dat zal het wel duidelijk maken:

Sub beveiligen()
    ActiveSheet.Unprotect
    ActiveSheet.Cells.SpecialCells(xlCellTypeVisible).Locked = False
    ActiveSheet.Cells.SpecialCells(xlCellTypeConstants).Locked = True
    ActiveSheet.Protect DrawingObjects:=True, Contents:=True, Scenarios:=True
End Sub

Den moet je dus telkens hetgeen wat achter With staat herhalen.

 

[jos1982]

Ja, dan is het mij wel duidelijk.

Ik had er vanmorgen al wat over gelezen op het internet, maar het kon zijn dat er nog meerdere redenen aan ten grondslag zouden liggen.

Nogmaals dank!

 

[edmoor]

Er zijn inderdaad meer redenen voor maar dat vergt nogal wat uitleg en voorbeelden. Met snelheid heeft het niks te maken.

 

[jansm]

Heerlijk zo'n discussie. With .... End maakt de code idd leesvriendelijker. Allen bedankt.