Alles verwijderen in cel achter ", ,"

[Peter2016]

Hallo,

Is het mogelijk dmv vba, om alles te verwijderen in een cel achter de combinatie ", ," (komma spatie komma) in bereik B2:B30.
Dus 123, 456, , 789,......
Blijft over: 123, 456
Zie bijlage

Alvast bedankt

 

[SjonR]

zo:

Sub kommakomma()

For Each cl In Range("B2:B30")
    cl.Value = Left(cl.Value, InStr(cl.Value, ", ,") - 1)
Next
End Sub

 

[HSV]

Lees het in het geheugen in, dat gaat sneller bij het wegschrijven dan cel voor cel.

Sub hsv()
Dim sv, i As Long
sv = Cells(1).CurrentRegion
  For i = 1 To UBound(sv)
    sv(i, 2) = Split(Replace(sv(i, 2), ", ,", "?"), "?")(0)
  Next i
Cells(1).Resize(UBound(sv), 2) = sv
End Sub

 

[Peter2016]

Heren, super bedankt wederom.

SjonR, bij jouw code kreeg ik de melding "een variabele is niet gedefinieerd"
Hsv, deze loopt als een trein, dus ga ik gebruiken.

Allebei een fijne jaarwisseling.

groet
Peter

 

[VenA]

Als je de melding "een variabele is niet gedefinieerd" krijgt dan moet je de variabele even declareren of Option Explicit weghalen.

In de sub van @HSV mag je het replace gedeelte ook weglaten en als je deze een beetje aanpast dan krijg je een iets nettere uitvoer. (geen ,spatie aan de voorkant )

Sub hsv()
  Dim sv, i As Long, c00 As String
  sv = Cells(1).CurrentRegion
    For i = 1 To UBound(sv)
    c00 = Split(sv(i, 2), ", ,")(0)
      sv(i, 2) = IIf(Left(c00, 1) = ",", Mid(c00, 3), c00)
    Next i
  Cells(1).Resize(UBound(sv), 2) = sv
End Sub

 

[HSV]

Of:

Sub hsv()
Dim sv, i As Long
  sv = Cells(1).CurrentRegion
    For i = 1 To UBound(sv)
      sv(i, 2) = Split(Replace(sv(i, 2), IIf(Left(sv(i, 2), 2) = ", ", ", ", ""), "", 1, 1), ", ,")(0)
    Next i
  Cells(1).Resize(UBound(sv), 2) = sv
End Sub

Of:

Sub hsv()
Dim sv, i As Long
  sv = Cells(1).CurrentRegion
    For i = 1 To UBound(sv)
      sv(i, 2) = Split(Mid(sv(i, 2), IIf(Left(sv(i, 2), 2) = ", ", 3, 1)), ", ,")(0)
    Next i
  Cells(1).Resize(UBound(sv), 2) = sv
End Sub

 

[snb]

Waarom niet replace ",,*",""

 

[HSV]

Die was inderdaad slimmer geweest. :thumb: