Als cel gevuld, dan andere cellen leeg

[dekrant]

Beste,

Kan iemand mij helpen bij het volgende:
Ik heb een excel bestand met een aantal kolommen in setjes van 3 (A,B en C) waarbij het de bedoeling is dat als men een X invult in de ene cel de andere 2 automatisch leeg gemaakt worden. Zodat men niet per ongeluk twee dingen aan kan kruisen in dat setje van 3.

Ik hoop dat mijn vraag duidelijk is. Bijgaand een voorbeeldbestandje

b.v.d.
Groeten
Sandra

 

[HSV]

In bladmodule:

Private Sub Worksheet_Change(ByVal Target As Range)
On Error GoTo einde
Application.EnableEvents = False
If UCase(Target.Value) = "X" Then
 Select Case Target.Column
    Case 2, 5, 8, 11, 14
     Target.Offset(, 1).Resize(, 2).ClearContents
    Case 3, 6, 9, 12, 15
     Union(Target.Offset(, -1), Target.Offset(, 1)).ClearContents
    Case 4, 7, 10, 13, 16
     Target.Offset(, -2).Resize(, 2).ClearContents
  End Select
 End If
einde:  Application.EnableEvents = True
End Sub

 

[edmoor]

Of deze:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim ColNo1 As Integer
    Dim ColNo2 As Integer

    Application.EnableEvents = False
    If UCase(Target.Value) = "X" Then
        Select Case Target.Column
            Case 2, 5, 8, 11, 14
                ColNo1 = Target.Column + 1: ColNo2 = Target.Column + 2
            Case 3, 6, 9, 12, 15
                ColNo1 = Target.Column - 1: ColNo2 = Target.Column + 1
            Case 4, 7, 10, 13, 16
                ColNo1 = Target.Column - 2: ColNo2 = Target.Column - 1
        End Select
        
        Cells(Target.Row, ColNo1).Value = vbNullString
        Cells(Target.Row, ColNo2).Value = vbNullString
    End If
    Application.EnableEvents = True
End Sub

@HSV:
Ik was er al mee bezig toen je die van jou plaatste.
Die had ik dus even gemist

 

[HSV]

Ik zie helaas geen meerwaarde.

 

[edmoor]

Ik ook niet, vandaar m'n extra opmerking er na

 

[HSV]

Dag Ed,

Die heb ik volledig gemist. :thumb:

 

[edmoor]

Omdat ik die erbij plaatste op het moment dat jij je "geen meerwaarde" opmerking plaatste
Maar zo heeft TS wat te kiezen

 

[dekrant]

fantastisch, ik ga ermee aan de slag.
Dankje voor jullie beider reactie.