Cel selecteren onder een datum

[don42]

Beste helpers

ik heb een tabblad (gespaard) met datums in een rij A3 t.m BC3
onder deze datums kopieer ik bedragen uit een andere sheet (invoer)
in sheet invoer staat een datum in cel F1
nu wil ik middels een button de cel onder de datum selecteren van tabblad gespaard
de rest van het kopiëren zal wel lukken

voorbeeld in F1 van tabblad invoer staat 10-10-2018
en deze datum staat in tabblad gespaard bv in cel E3
dan moet cel E4 geselecteerd
is dit mogelijk?

Don

 

[Haije]

Hallo Don,

dat is vast wel mogelijk, maar plaats eens een Excel (voorbeeld) bestand waar de beschreven situatie in voorkomt.
LET OP: er mogen geen "gevoelige" informatie in het bestand staan

 

[emields]

Een voorbeeld bestand is wenselijk.

 

[don42]

kunnen jullie hier iets mee?

heb snel iets in elkaar gezet, orgineel staat vol met namen en bedragen

Bekijk bijlage spaar3.xlsx

 

[don42]

onderstaande code gebruik ik in tabblad gespaard

Private Sub worksheet_activate()
 Range("A4").End(xlToRight).Offset(0, 1).Select
End Sub

daarmee wordt dus de eerste lege cel in rij geselecteerd (en de gegevens uit invoer geplakt)
maar met mijn vraag met de datum zou het veel handiger zijn

 

[HSV]

Private Sub CommandButton1_Click()
Dim r As Range
Set r = Range("b2").CurrentRegion
  With Sheets("gespaard")
    .Cells(Rows.Count, Application.Match(Range("f1"), .Rows(3), 0)).End(xlUp).Offset(1).Resize(r.Rows.Count) = r.Value
  End With
End Sub

 

[don42]

Wow #6
dit komt heel dicht in de buurt
maar is het mogelijk dat de data overschreven wordt?
of eerst gewist en opnieuw 'geplakt'
nu komt de hele invoer er onder aan
voorbeeld:
er sparen 80 personen
heb ik dus 80 bedragen, mocht er een bedrag fout zijn ingetikt wil ik het aanpassen middels de command button

 

[HSV]

Dat is wel mogelijk.

Private Sub CommandButton1_Click()
Dim r As Range, bereik As Range
Set r = Range("b2").CurrentRegion
  With Sheets("gespaard")
  Set bereik = .Cells(4, Application.Match(Range("f1"), .Rows(3), 0))
    bereik.CurrentRegion.Offset(3).ClearContents
    bereik.Resize(r.Rows.Count) = r.Value
  End With
End Sub

 

[don42]

#8

Dit werkt prima, hoe te handelen als er een lege cel is dan stopt het kopiëren
als voorbeeld gebruik ik deze

Range("p2", Range("p1048576").End(xlUp)).Copy

* zou het kunnen oplossen om een 0 te noteren

 

[HSV]

Vanwaar lege cellen?

Als ik in het klad iets moet optellen staat bij mij alles op komma gecentreerd onder elkaar.
Zulke dingen leerde je al in klas twee van de lagere school.

 

[don42]

Je hebt gewoon een punt
het gaat in feite zo
naam1 spaart 10
naam 2 spaart 15
naam 3 spaart (niets dan blijft de cel leeg) maar zoals gezegd is dit met een nul opgelost
bedankt voor de moeite en je fijne hulp

 

[HSV]

Graag gedaan,

Natuurlijk kan het wel.
Ik bedoel er mee dat de codes onnodig gecompliceerd worden.

Probeer het maar eens.

Private Sub CommandButton1_Click()
Dim r As Range, kl As Long
Set r = Range("b2", Cells(Rows.Count, 2).End(xlUp))
  With Sheets("gespaard")
   kl = Application.Match(Range("f1"), .Rows(3), 0)
    .Range(.Cells(4, kl), .Cells(Application.Max(4, .Cells(Rows.Count, kl).End(xlUp).Row), kl)).ClearContents
    .Cells(4, kl).Resize(r.Rows.Count) = r.Value
  End With
End Sub

 

[don42]

idd de code ziet er steeds indrukwekkender uit
maar het werkt wel perfect
:d
ik ben er blij mee