cellen samenvoegen

[citrosphere]

Goedemiddag,

Wie kan mij helpen met het volgende probleem :

BM90858 170649
BM90295 171713
BM90189 172196
BM90050 173113
BM90050 173115
BM90020 173118
BM90115 173121

Twee kolommen met nummers, de eerste is het hoofdnummer.

Ik wil bijvoorbeeld het volgende krijgen : BM90050 173113,173115

Iemand een idee ?

ALvast bedankt,,

Ed

 

[Wigi]

Plak dit in een nieuwe module:

Sub samenzetten()
    Dim l As Long
    Application.ScreenUpdating = False
    sorteren
    For l = Range("A" & Rows.Count).End(xlUp).Row To 2 Step -1
        
        If Range("A" & l) <> "" Then
            If Range("A" & l - 1) = Range("A" & l) Then
                Range("B" & l - 1) = Range("B" & l - 1) & ", " & Range("B" & l)
                Range("A" & l).Resize(, 2).ClearContents
            End If
        End If
    Next
    sorteren
    Application.ScreenUpdating = True
    MsgBox "Klaar."
End Sub

Sub sorteren()
    Range("A1:B" & Range("A" & Rows.Count).End(xlUp).Row).Sort Key1:=Range("A1"), Order1:=xlAscending, Key2:=Range("B1"), Order2:=xlAscending
End Sub

Wigi

 

[citrosphere]

Bedankt,

Ik heb het werkend.

Goed weekend.

Gr ed

 

[Wigi]

Zet de vraag dan op opgelost aub.