CommandButton

[appie36]

Hallo,

Ik heb een tabel met gegevens, met een CommandButton maak ik daar een PDF van. Zover gaat het goed,
Ik dacht ik maak een dashboard met alles bij elkaar en de CommandButton ook daar bij om snel de PDF te kunnen afdrukken

Helaas werkt dit niet, moet de CommandButton altijd op het zelfde blad staan dan waar de opdracht moet worden uitgevoerd of kan dat ook anders.

Mvg,
Ab

 

[Ben]

Dag Ap,
Graag een bestandj bjvoegen, glazebol is wazig.

groetjes Ben

 

[appie36]

Ik ben er al uit, zie code.
De knop staat op Sheet(Dashboard), daar zit deze code onder.
Het scherm knippert wel even maar het werkt.

Private Sub CommandButton1_Click()
Sheets("Planning").Select
ActiveSheet.ExportAsFixedFormat _
    Type:=xlTypePDF, _
    FileName:=Range("D6") & " Meststoffen Planning", _
    Quality:=xlQualityStandard, _
    IncludeDocProperties:=False, _
    IgnorePrintAreas:=False, _
    From:=1, _
    To:=5, _
    OpenAfterPublish:=True
    
Sheets("Dashboard").Select


End Sub

 

[edmoor]

Dit is voldoende:

Private Sub CommandButton1_Click()
    With Sheets("Planning")
        .ExportAsFixedFormat _
        Type:=xlTypePDF, _
        Filename:=.Range("D6") & " Meststoffen Planning", _
        OpenAfterPublish:=True
    End With
End Sub

 

[appie36]

Inderdaad, stuk korter en doet het zelfde, bedankt.

Als je twee maal op de knop klikt dan krijg je foutmelding, op zich geen probleem. Als het goed is klikt men er ook maar 1x op, maar is zo iets nog te ondervangen met een msgbox of wat anders?

Mvg,
Ab

 

[edmoor]

Als je zegt een foutmelding te krijgen is het wel zo handig deze er ook bij te vertellen.

 

[appie36]

Ja dat is inderdaad niet zo handig zonder voorbeeld, zie foto

Je kan hem wel beindigen gelukkig, de boel loopt niet vast

 

[edmoor]

Dat staat los van de code.
Hij probeert een document met dezelfde naam op te slaan en dat is kennelijk niet toegestaan in de map waar dat wordt gedaan.
Is het belangrijk dat PDF document op te slaan of wil je hem alleen openen?

 

[AHulpje]

Zo:

Sub CommandButton1_Click()
    On Error GoTo errhandler
    With Sheets("Planning")
        .ExportAsFixedFormat _
        Type:=xlTypePDF, _
        Filename:=.Range("D6") & " Meststoffen Planning", _
        OpenAfterPublish:=True
    End With
    Exit Sub
errhandler:
    MsgBox "Bestand kon niet worden opgeslagen, mogelijk is het document nog geopend."
End Sub

 

[edmoor]

Kan natuurlijk.
Maar daarmee wijzig je alleen de foutmelding in plaats van de fout te verhelpen.

 

[appie36]

Edmoor, helemaal geweldig. Dit precies wat ik wil.

 

[edmoor]

Ik denk dat je AHulpje bedoelt

 

[AHulpje]

Maar van edmoor moet het eigenlijk zo, en dat is inderdaad beter:

Sub CommandButton1_Click()    With Sheets("Planning")
    If IsFileOpen(Range("D6") & " Meststoffen Planning.pdf") Then
        MsgBox "Bestand kon niet worden opgeslagen, het document is nog geopend.", vbCritical, "Foutmelding"
    Else
        .ExportAsFixedFormat _
        Type:=xlTypePDF, _
        fileName:=.Range("D6") & " Meststoffen Planning.pdf", _
        OpenAfterPublish:=True
    End If
    End With
End Sub


Function IsFileOpen(fileName As String)
    Dim fileNum As Integer
    Dim errNum As Integer
    Dim errDescription As String
    
    If Len(Dir(fileName)) > 0 Then
        On Error Resume Next
        fileNum = FreeFile()
        
        Open fileName For Input Lock Read As #fileNum
        errNum = Err
        errDescription = Err.Description
        Close fileNum
        On Error GoTo 0
        
        Select Case errNum
            Case 0
                IsFileOpen = False
            
            Case 70
                IsFileOpen = True
        
            Case Else
                MsgBox errDescription, vbCritical, "Foutmelding"
        End Select
    End If
End Function

 

[HSV]

Je kan Acrobat ook zo sluiten.

Sub CommandButton1_Click()
 Shell "taskkill  /IM Acrobat.exe"
 Application.Wait DateAdd("s", 2, Now) 'even de tijd gunnen om Acrobat te sluiten
    With Sheets("Planning")
        .ExportAsFixedFormat Type:=xlTypePDF, Filename:=.Range("D6") & " Meststoffen Planning", OpenAfterPublish:=True
    End With
end sub

 

[appie36]

Allemaal bedankt voor het meedenken, opties te over zo te zien.

ik zal het draadje afsluiten