Controleren of map bestaat

[Wampie Beukies]

hallo,

Om te controleren of een map reeds bestaat, heb ik de volgende code gevonden, maar hij geeft in alle gevallen aan dat de map reeds bestaat, dus ook wanneer dat niet zo is.

Sub NieuweMap()
'
' NieuweMap Macro
''
    Dim myValue As String
    Dim sFolderPath As String
    sFolderPath = "E:\Scauting\" & myValue
    
    myValue = InputBox("Voer het gewenste jaartal in")
    If Dir(sFolderPath, vbDirectory) <> vbNullString Then
        MsgBox "Deze map bestaat reeds"
    Else: MsgBox "Deze map bestaat nog niet"
       
    End If

End Sub

Wat klopt er niet?

 

[RogerS]

sFolderPath = "E:\Scauting\" & myValue
    
myValue = InputBox("Voer het gewenste jaartal in")

Deze staan in de verkeerde volgorde. Je stelt nu eerst sFolderPath in en vraagt daarna om input.

 

[Wampie Beukies]

Ok top en eigenlijk heel logisch uiteraard! Thank you very much!

 

[OctaFish]

En als je wilt dat de gebruiker alleen maar jaartallen mag invoeren, zou ik myValue als Integer definiëren, niet als String. En eventueel controleren of de input inderdaad een getal is of niet. En als slot: waarom maak je de map niet gelijk aan, als aan de voorwaarden (myValue = geldig jaartal) is voldaan? Wat moet je als gebruiker met die messagebox als de map niet bestaat? Op dezelfde regel waar nu de msgbox staat, kun je net zo goed een regel maken (met MkDir) die het pad aanmaakt, kun je gelijk verder met de code.

 

[Wampie Beukies]

Die code heb ik er bijstaan OctaFish, maar die had ik eruit gehaald om een zo schoon mogelijke code te posten. De aanpassing naar Integer i.p.v. String zal ik ter harte nemen.
Waarvoor dank.

 

[jkpieterse]

Merk op, dat de gegeven oplossing om te checken of een map bestaat ten onrechte aangeeft dat die map bestaat als de map erboven toevallig een bestand bevat met de mapnaam. Beter is deze functie:

Function DirectoryExists(Directory As String) As Boolean
    DirectoryExists = False
    If Len(Dir(Directory, vbDirectory)) > 0 Then
        If (GetAttr(Directory) And vbDirectory) = vbDirectory Then
            DirectoryExists = True
        End If
    End If
End Function

 

[edmoor]

Waarbij je de regel DirectoryExists = False weg kan laten

 

[Wampie Beukies]

Het heeft even geduurd, maar zit nu naar deze code te kijken. Hoe verwerk ik dit in mijn code?

 

[edmoor]

Zoiets:

Sub NieuweMap()
    sFolder = InputBox("Voer het gewenste jaartal in")
    If DirectoryExists("E:\Scauting\" & sFolder) Then
        MsgBox "Deze map bestaat reeds"
    Else
        MsgBox "Deze map bestaat nog niet"
    End If
End Sub

Function DirectoryExists(ByVal Directory As String) As Boolean
    If Len(Dir(Directory, vbDirectory)) > 0 Then
        If (GetAttr(Directory) And vbDirectory) = vbDirectory Then
            DirectoryExists = True
        End If
    End If
End Function

 

[snb]

Ik zou me beperken tot (cfr. @Octa):

Sub M_snb()
    On Error Resume Next
    MkDir "E:\Scouting\" & InputBox("jaar")
End Sub

NB. Mijn spellingscorrectie kent geen scauting.

 

[Wampie Beukies]

@snb

NB. Mijn spellingscorrectie kent geen scauting.

Misschien toch eens googelen. Is best een leuk bedrijf.