Cursief splitsen

[MMV]

Beste allen,

Wellicht kunnen jullie mij ergens mee helpen.

Ik wil een woordenlijst in elkaar draaien.Mijn bronbestanden zijn echter in een format waarmee ik niets kan.

Ik wil de Engelse term splitsen van de Nederlandse term.

De Nederlandse termen staan cursief. Deze zou ik graag in een aparte kolom willen.

Gescheiden dus van de Engelse termen.

Weet iemand hier een oplossing voor?

Als bijlage een voorbeeld bestandje!

 

[Wigi]

Hiermee lukt het:

Sub splitscursief()

    Dim r As Range
    Dim i As Integer
    
    Application.ScreenUpdating = False
    
    Columns("B:C").ClearContents
    
    For Each r In Range("A1:A" & Range("A" & Rows.Count).End(xlUp).Row)
        
        i = 0
        
        Do
            i = i + 1
        Loop Until r.Characters(i + 1, 1).Font.Italic = True
        
        r.Offset(, 1).Value = Trim(Left(r.Value, i))
        r.Offset(, 2).Value = Trim(Right(r.Value, Len(r.Value) - i))

    Next
    
    Application.ScreenUpdating = True
    
End Sub

Wigi

 

[snb]

Interessant object: characters.

Ik kwam daarmee tot de volgende code

Sub tst()
  On Error Resume Next
  For Each cl In Columns(1).SpecialCells(2)
    If Err.Number > 0 Then End
    j = 1
    Do Until cl.Characters(j, 1).Font.Italic Or j > Len(cl)
      j = j + 1
    Loop
    If j < Len(cl) Then Range(cl, cl.Offset(, 1)) = Split(Mid(cl, 1, j - 2) & "|" & Mid(cl, j - 1, 100), "|")
  Next
End Sub

 

[MMV]

Bedankt voor jullie snelle reacties. Hierbij terugkoppeling:

To SNB: Ik heb je code uitgeprobeerd en het bleek dat hij bij de tweede kolom bij elke regel nog 1 spatie liet staan. Dat zijn nog een hoop bestanden welke ik dan nogmaals moet aanpassen.

To WIGI: Jouw code werkte goed er bleven geen spaties staan. Het enige nadeel is dat de opmaak veranderd. Maar daar kan ik mee leven.

Nogamaals bedankt voor jullie hulp! Ik sluit de vraag!

 

[Wigi]

Voeg dan dit toe:

Columns(2).Font.Bold = True
Columns(3).Font.Italic = True