Datum berekenen aan de hand van een weeknummer

[Joagertje]

Hallo,

Ik heb even een vraag. Ik had een document waarin automatisch de data werden berekend aan de hand van het jaartal en weeknummer. Dit ging voor dit jaar goed, maar als ik dit wil kopieeren naar 2016 krijg ik de verekeerde gegevens. Als ik voor 2016 week 1 kies krijg ik de data van week 53. Dit werkt dat in heel 2016 zo door. Ik maak gebruik van Office 2010.

Ik heb het voorbeeld in de bijlage even bijgevoegd.

 

[snb]

Kijk eens in een officiële Nederlandse agenda. Ook daar valt 1 januari 2016 in week 53 van 2015.

Nadere uitleg vind je hier: http://www.snb-vba.eu/VBA_ISO_weeknummer.html

 

[Joagertje]

Ik weet dat ik bij 1 januari 2016 ook week 53 krijg maar als ik week 1 2016 kies krijg ik als datum voor de maandag 28 december in plaats van 4 januari. Voor week 2 wordt dit dan 4 januari in plaats van 11 januari enz.

 

[edmoor]

Dat is dus de andere kant op. Waar kies je in Excel voor week 1 van 2016? Heb je daar een kalender of zo voor?

 

[Joagertje]

Het document is niet door mij gemaakt. Ik vul alleen het jaartal (rij 2) en de week (rij3) in en de formule genereert de datum in rij 4 dmv de formule;

"=DATUM(B2;1;1)+7*B3-WEEKDAG(DATUM(B2;1;1);2)-6"

 

[snb]

Moet zijn voor de maandag:

"=DATUM(B2;1;4)-WEEKDAG(DATUM(B2;1;4);2)+7*(B3-1)+1"

voor de dinsdag:

"=DATUM(B2;1;4)-WEEKDAG(DATUM(B2;1;4);2)+7*(B3-1)+2"

 

[MarcelBeug]

Bekijk bijlage datum en weeknummer MB.xlsx

Ik heb de formule op regel 4 zo gemaakt, dat je 1 uniforme formule hebt, oftewel de formule in B4 doorgetrokken naar rechts:

=DATUM(Jaar;1;4)+7*Week-WEEKDAG(DATUM(Jaar;1;4);2)-6+REST(KOLOMMEN($B:B)-1;7)

"Jaar" en "Week" zijn gedefinieerde namen voor het betreffende jaar en weeknummer, wat ook nogal een gepruts is door het gebruik van samengevoegde cellen:

Jaar =INDEX(Blad1!$2:$2;;KOLOM(Blad1!B:B)-REST(KOLOMMEN(Blad1!$B:B)-1;7))
Week =INDEX(Blad1!$3:$3;;KOLOM(Blad1!B:B)-REST(KOLOMMEN(Blad1!$B:B)-1;7))

Zoals ook al verwerkt in de bijdrage van snb: bepalend is 4 januari: dat valt altijd in week 1 volgens de ISO norm.

 

[Joagertje]

Dit is inderdaad de oplossing. Bedankt voor jullie hulp.