Directory selecteren dmv. Dialog

[RIANXL]

Ik wil een button maken met als resultaat een string met een directory bijvoorbeeld: "c:/mapnaam/submapnaam/" die geselecteerd moet worden via een windows opzoekvenster.

Via deze code krijg ik de volgende melding: "Methode FileDialog van object _Application is mislukt"

Private Sub Knop75_Click()
Dim fileName As String
Dim result As Integer

With Application.FileDialog(msoFileDialogFolderPicker)
.Title = "Search for road description"
.AllowMultiSelect = False
.InitialFileName = CurrentProject.Path
result = .Show
If (result <> 0) Then
Me.comRdPad = Trim(.SelectedItems.Item(1))
Me.Save.Enabled = True
End If
End With

End Sub

En via de manier zoals beschreven op de onderstaande website zie ik geen mogelijkheid om een directory zonder file te selecteren.:shocked:

http://www.mvps.org/access/api/api0001.htm

Heeft iemand hier misschien een oplossing voor?

 

[Guus2005]

De routine die ik gebruik:

Public Function SelectOneFile2(strCurDir As String, strDialogTitle As String, intFilter As FileType) As String
   ' Hetzelfde als SelectOneFile maar dan met behulp van de built-in Application.FileDialog.
   On Error GoTo Err_SelectOneFile2

   Dim fd As FileDialog
   Dim varSelectedItem As Variant
   Dim strFile As String
   
   'Create a FileDialog object as a Folder Picker dialog box.
   Set fd = Application.FileDialog(msoFileDialogFilePicker)  'of [B]msoFileDialogFolderPicker[/B]
   strFile = ""
   
   With fd
      .Title = strDialogTitle
      .ButtonName = "&Select"
      .InitialView = msoFileDialogViewDetails
      'Add a filter that includes MDB files and make it the first item in the list.
      .Filters.Clear
      .Filters.Add "Access databases", "*.mdb", 1
      .Filters.Add "Alle bestanden", "*.*", 2
      'Sets the initial file filter to number 1.
      .FilterIndex = 1
      If .Show = -1 Then
         For Each varSelectedItem In .SelectedItems
            strFile = strFile & ", " & varSelectedItem
         Next varSelectedItem
      Else
         strFile = ""
      End If
   End With

    SelectOneFile2 = strFile

Exit_SelectOneFile2:
   Set fd = Nothing
   Exit Function

Err_SelectOneFile2:
   ErrorProc Err, Error$, "SelectOneFile2", "basFileDialog"
   Resume Exit_SelectOneFile2

End Function

Met deze code selecteer je een bestand. Als je msoFileDialogFolderPicker gebruikt kan je ook directories selecteren. Wees maar even creatief. Rechtsklik op msoFileDialogFolderPicker en selecteer definities voor meer mogelijkheden.

Het kan zijn dat je een reference mist: Requires reference to Microsoft Office 11.0 Object Library.


Succes!

 

[RIANXL]

Die verwijzing was het inderdaad! bedankt voor de hulp!:thumb: