Door middel van macro bepaalde cellen kopiëren naar nieuw tabblad

[erwin87]

Beste,

ik zit met de volgende vraag, ik zou graag vanaf bv Blad1 cel A1 Tot Cel D51 willen kopiëren naar een nieuw tabblad met de hulp van een macro maar het tabblad moet dan ook de naam krijgen van bv Blad1 Cel H4.
als ik dit herhaal vanaf blad1 zou dan weer een nieuw tabblad moeten komen maar ook rechts van de tabladen aansluiten.

Is dit mogelijk?


mvg

 

[edmoor]

Zoiets:

Sub BladToevoegen()
    Dim shName As String
    Dim i As Integer
    
    shName = Sheets("Blad1").Range("H4")
    
    If shName <> "" Then
        For i = 1 To Worksheets.Count
            If Worksheets(i).Name = shName Then Exit Sub
        Next i

        Worksheets.Add(After:=Worksheets(Worksheets.Count)).Name = shName
    
        For i = 1 To 51
            Sheets(shName).Range("A" & i) = Sheets("Blad1").Range("A" & i)
        Next i
    End If

End Sub

 

[erwin87]

Beste,

dit is wat ik bedoel maar nu word alleen kolom a geselecteerd
ik heb een voorbeeld bestandje wat je op blad 1 ziet zou hij moeten kopiëren

Bekijk bijlage test 2.xlsm

alvast bedankt

mvg

 

[edmoor]

Eigenlijk wil je dus een kopie van Blad1 naar een nieuw blad met de naam die in de samengevoegde cellen I6 t/m M6 staat en dan zonder de gegevens in het bereik G6 t/m M6. Op die manier gaat dan ook de layout mee.
Is dat wat je bedoeld?

 

[erwin87]

Dat is perfect wat het zou moeten zijn.
is het mogelijk hierbij nog hulp te krijgen?

alvast bedankt

Mvg

 

[edmoor]

Test het bijgevoegde blad maar eens. In het blad Start geef je een naam op. Er wordt dan bij een druk op de knop een kopie gemaakt van het blad Sjabloon. Deze wordt als nieuw blad aan het einde van de bestaande reeks toegevoegd en krijgt de naam zoals opgegeven in het blad Start. Mocht je een naam opgeven van een bestaand blad dan krijg je daar een melding van en stopt de routine.

Dit is de code achter de knop:

Sub KopieSjabloon()
    Dim shName As String
    
    shName = Sheets("Start").Range("NieuwBlad")
    
    If shName <> "" Then
        For i = 1 To Worksheets.Count
            If Worksheets(i).Name = shName Then
                MsgBox "Een blad met de naam " & shName & " bestaat al", vbInformation
                Exit Sub
            End If
        Next i
    
        Sheets("Sjabloon").Copy After:=Sheets(Sheets.Count)
        Sheets(ThisWorkbook.Sheets.Count).Name = shName
    End If
End Sub

"NieuwBlad" is de naam van de cel waar je de nieuwe naam ingeeft. Een benoemde cel dus. Zo ben je ook vrij in de layout van het blad Start. Het blad Sjabloon kun je opmaken zoals je wilt.

Bekijk bijlage test 2.xlsm

 

[erwin87]

heel fel bedankt dit is perfect

ik zet de vraag ook als opgelost

nog eens bedankt

mvg