eerste datum in 2023 weergeven

[mmnijssen]

Hallo,

ik heb 3 tabellen, een tabel met datum uit de geschiedenis, een tweede tabel met de datum uit de huidige data, in de derde kolom moet een formule staan welke naar de eerste 2 tabellen kijkt en vervolgens de eerste datum vermeld in 2023.
Wie o wie kan mij helpen?

Alvast bedankt!

 

[sylvester-ponte]

een van de vele mogelijkheden:

=ALS(JAAR(Tabel1[@datum])=2023;MIN(Tabel1[@datum];Tabel2[@datum]);Tabel2[@datum])

 

[AlexCEL]

Nog eentje dan:

=MIN(Tabel2[@datum];Tabel1[@datum]*(1+10*(Tabel1[@datum]<44927)))

 

[mmnijssen]

Bedankt voor beide antwoorden, ze beide werken prima. Ik heb alleen een fout gemaakt, de nummers in tabel 1 staan niet in dezelfde volgorde als tabel 2 en 3, er zal dus iets van een zoekformule in verwerkt moeten worden

 

[AlexCEL]

Gebruik je Excel 365?

 

[mmnijssen]

ja, 365.

 

[peter59]

Dan kan het met power query.

 

[AlexCEL]

Misschien zoiets qua Excel 365 formule?

=LET(x;ALS.FOUT(VERT.ZOEKEN([@nr];Tabel1;2;0);0);y;ALS.FOUT(VERT.ZOEKEN([@nr];Tabel2;2;0);0);k;ALS(JAAR(x)=2023;x;EXP(99));l;ALS(JAAR(y)=2023;y;EXP(99));MIN(k;l))

 

[sylvester-ponte]

of

=LET(nr;VERT.STAPELEN(Tabel1[nr];Tabel2[nr]);datum;VERT.STAPELEN(Tabel1[datum];Tabel2[datum]);MIN(FILTER(datum;(nr=Tabel3[@nr])*(JAAR(datum)=2023))))

 

[HSV]

Ook leuk; dynamisch.

=LET(nr;VERT.STAPELEN(Tabel1[nr];Tabel2[nr]);datum;VERT.STAPELEN(Tabel1[datum];Tabel2[datum]);x;SORTEREN.OP(HOR.STAPELEN(nr;datum);datum);INDEX(INDEX(x;;2);VERGELIJKEN(Tabel3[nr];ALS(JAAR(INDEX(x;;2))=2023;INDEX(x;;1);"");0)))

 

[AlexCEL]

Het lijkt een heel simpel probleem, tot je ermee bezig gaat...

 

[snb]

Ik kwam een heel eind met de volgende matrixformule:

=MIN(IF((Tabel2[nr]=J5)*(YEAR(Tabel2[datum])=2023);Tabel2[datum]);IF((Tabel1[nr]=J5)*(YEAR(Tabel1[datum])=2023);Tabel1[datum]))