Email opbouw check formule.

[heponij]

Beste allen,

Zelf denk ik dat ik in een visuele cirkel zit en daar kom ik maar niet uit.
Wie zou mij kunnen helpen, met de door mij zelf gemaakte formule (of bestaat er al iets waarmee een postcode opbouw kan checken).
=ALS(EN(ISGETAL(VIND.SPEC("@";A1));ISGETAL(VIND.SPEC(".";A1));ISGETAL(VIND.SPEC(" ";A1)));"Juist Mail Adres";"Onjuist Mail Adres")
Bij de vet gedrukte vraag loop ik vast deze geeft de fout waarde #WAARDE.
Indien ik deze apart controleer dan gaat het goed.
Hoe kan ik dat oplossen.
Ik werk met met Office 365.

B.v.d. voor alle tijd en moeite.

M.v.g. Herman

 

[AlexCEL]

Er zit nooit een @-teken in een postcode... Dus bedoel je een e-mail adres? Een voorbeeldje bij een vraag helpt altijd...
Ik neem verder aan dat GEEN spatie in een e-mail adres mag zitten. Voldoet dit dan?

=ALS(EN(ISGETAL(VIND.SPEC("@";A1));ISGETAL(VIND.SPEC(".";A1));NIET(ISGETAL(VIND.SPEC(" ";A1))));"Juist Mail Adres";"Onjuist Mail Adres")

Edit: hier nog een wat kortere optie:

=ALS(ISGETAL(VERGELIJKEN("*@*.?*";A1;0));"J";"Onj")&"uist Mail Adres"

 

[Senso]

Het is niet erg zinvol om een nieuwe topic te openen. Je had direct een voorbeeldbestand moeten plaatsen. Dan kun je jouw opzet en gewenste resultaten tonen.

 

[edmoor]

Dit is een visuele cirkel:

 

[heponij]

Sorry het moet een Email adres zijn.

Mijn excuus. Herman

 

[HSV]

Kijkt alleen of beide tekens erin staan en niet op welke plek.

=AANTAL(VIND.SPEC({"@";"."};A1))=2

 

[heponij]

Email adres check.

HSV bedankt dit werkt nog beter.
Maar ik zit nog steeds met de Spatie daar kom ik maar niet uit.

Herman

 

[AlexCEL]

Wat vonden we dan van deze uit #2?

=ALS(ISGETAL(VERGELIJKEN("*@*.?*";A1;0));"J";"Onj")&"uist Mail Adres"

 

[HSV]

Iets in deze trend.

=ALS(NIET(ISFOUT(VIND.SPEC(" ";A1)));"Onj";ALS(ISGETAL(VERGELIJKEN("*@*.?*";A1;0));"J";"Onj"))&"uist Mail Adres"

 

[heponij]

Iets in deze trend.

=ALS(NIET(ISFOUT(VIND.SPEC(" ";A1)));"Onj";ALS(ISGETAL(VERGELIJKEN("*@*.?*";A1;0));"J";"Onj"))&"uist Mail Adres"

Hallo Harry,

Zelf ben ik ook nog bezig geweest en heb de volgende oplossing gevonden;
=ALS(EN(AANTAL(VIND.SPEC({"@";"."};A1))=2;AANTAL(VIND.SPEC(" ";A1))=0);"J";"Onj")&"uist Mail Adres"
Maar ben ben er alleen uitgekomen dankzij jullie prachtige voorbeelden.
Nogmaals bedankt voor alle moeite en tijd.

M.v.g. Herman