email verzenden

[edmoor]

Inderdaad. Geen antwoord op de gestelde vragen, dus dat schiet niet op.

 

[ACER10]

mail

Sorry ik was enkele dagen buiten strijd, geveld door COVID maar nu beetje beter... wel nog in afzondering voor 2 dagen...

Ik zet hier nog eens de code die maar niet wil werken bij mij...
wat gaat er mis ? ik krijg een fout in de aangeduide regel. <----

Sub ZendMail()
Dim OutApp As Object
Dim OutMail As Object


    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    With Sheets("Uitslag Dag")
         Bestand = Environ("temp") & "\" & "Uitslag Dag" & .Range("B1") & ".pdf"
        
        .Range("B1:G40").ExportAsFixedFormat Type:=xlTypePDF, Filename:=Bestand                  <-----fout in deze regel

        StrTo = "edpo@telenet.be"
        StrSubject = "Uitslag"
        strbody = "Beste" & vbCrLf & vbCrLf & _
               "Als bijlage ontvangt U hierbij de uitslag" & vbCrLf & vbCrLf & _
               "groet," & vbCrLf & vbCrLf & _
               "De verantwoordelijke"
    End With

    With OutMail
        .To = StrTo
        .Subject = StrSubject
        .Body = strbody
        .Attachments.Add Bestand
        .Display

    End With



    Kill Bestand
    Set OutMail = Nothing
    Set OutApp = Nothing

    
    
End Sub

 

[edmoor]

Als je zegt een foutmelding te krijgen vertel er dan ook bij welke dat is.

 

[ACER10]

Fout melding

Hierbij de fout die ik krijg in een pop-up.

 

[AD1957]

Probeer dit eens.

With Sheets("Uitslag Dag")
       [COLOR="#FF0000"] .Visible = True[/COLOR]
         Bestand = Environ("temp") & "\" & "uitslag dag " & .Range("B1") & ".pdf"
        .Range("B1:G40").ExportAsFixedFormat Type:=xlTypePDF, Filename:=Bestand

        StrTo = emailadres
        StrSubject = "bla bla bla"
        strbody = "Beste" & vbCrLf & vbCrLf & _
               "Als bijlage ontvangt U hierbij de uitslag" & vbCrLf & vbCrLf & _
               "groet," & vbCrLf & vbCrLf & _
               "naam verzender"
         [COLOR="#FF0000"].Visible = False[/COLOR]
    End With

 

[edmoor]

Wat staat er letterlijk in Sheets("Uitslag Dag").Range("B1") ?
Dat is in #17 ook al geopperd.

 

[JEC.]

Run dit eens

Sub jec()
 Dim xFile
 xFile = Environ("temp") & "\" & "Uitslag Dag" & cleaning(Sheets("Uitslag Dag").Range("B1")) & ".pdf"
 Sheets("Uitslag Dag").Range("B1:G40").ExportAsFixedFormat xlTypePDF, xFile
 
 With CreateObject("outlook.application").createitem(0)
   .to = "edpo@telenet.be"
   .Subject = "Uitslag"
   .body = "Beste" & vbCrLf & vbCrLf & "Als bijlage ontvangt U hierbij de uitslag" & vbCrLf & vbCrLf & "groet," & vbCrLf & vbCrLf & "De verantwoordelijke"
   .Attachments.Add xFile
   .display
 End With
 
 Kill xFile
End Sub

Function cleaning(x As String) As String
 With CreateObject("vbscript.regexp")
   .Global = True
   .Pattern = "[\\/:?<>|\*""]"
   cleaning = .Replace(x, "")
 End With
End Function

 

[ACER10]

blad UITSLAG DAG

Hierbij het gevraagde blad

 

[edmoor]

De inhoud van B1 is dus fout.
Een bestandsnaam mag geen / tekens bevatten.

 

[JEC.]

Je gebruikt tekens in je bestandsnaam die niet mogen zoals ik al had verwacht. Mijn laatste voorstel lost dat op.

Dit zou ook voldoende moeten zijn

Sub jec()
 Dim xFile
 xFile = Environ("temp") & "\" & "Uitslag Dag" & Replace(Sheets("Uitslag Dag").Range("B1"), "/", "-") & ".pdf"
 Sheets("Uitslag Dag").Range("B1:G40").ExportAsFixedFormat xlTypePDF, xFile
 
 With CreateObject("outlook.application").createitem(0)
   .to = "edpo@telenet.be"
   .Subject = "Uitslag"
   .body = "Beste" & vbCrLf & vbCrLf & "Als bijlage ontvangt U hierbij de uitslag" & vbCrLf & vbCrLf & "groet," & vbCrLf & vbCrLf & "De verantwoordelijke"
   .Attachments.Add xFile
   .display
 End With
 
 Kill xFile
End Sub

 

[ACER10]

mail

Beste JEC

Bedankt voor uw tussenkomst en oplossing want het werkt....
Ik heb nog een vraagje, als ik nu een 2de blad uit het zelfde werkblad wil meesturen
terzelfdertijd en met de zelfde macro kan dit , en wat moet er worden aangepast?
bv blad genaamd FORM (A1 : K25)

Ed

 

[JEC.]

Hier neem ik even aan dat A1:K25 het printbereik moet zijn in tabblad FORM

Sub jec()
 Dim a(1), it, sp, x As Long
 For Each it In Array("Uitslag Dag|B1:G40", "FORM|A1:K25")
   sp = Split(it, "|")
   a(x) = Environ("temp") & "\" & sp(0) & Replace(Sheets(sp(0)).Range("B1"), "/", "-") & ".pdf"
   Sheets(sp(0)).Range(sp(1)).ExportAsFixedFormat xlTypePDF, a(x)
   x = x + 1
 Next
 
 With CreateObject("outlook.application").createitem(0)
   .to = "edpo@telenet.be"
   .Subject = "Uitslag"
   .body = "Beste" & vbCrLf & vbCrLf & "Als bijlage ontvangt U hierbij de uitslag" & vbCrLf & vbCrLf & "groet," & vbCrLf & vbCrLf & "De verantwoordelijke"
   .Attachments.Add a(0)
   .Attachments.Add a(1)
   .display
 End With
 
 Kill a(0)
 Kill a(1)
End Sub

 

[ACER10]

Bedankt

Beste JEC,

Heel erg bedankt voor de oplossingen, ik heb weer wat bijgeleerd over het fantastische Excel...

Ik zet mijn vraag als opgelost.

Bedankt aan iedereen die reageerde

Ed

 

[snb]

@JEC

Mooie illustraite waarom spaties in bladnamen te vermijden:

Sub M_snb()
  For Each it In Array("'Uitslag Dag'!B1:G40", "'FORM'!A1:K25")
     Evaluate(it).ExportAsFixedFormat 0, Environ("temp") & "\" & Evaluate(it).Parent.Name & Replace(Evaluate(it).Cells(1), "/", "-") & ".pdf"
  Next
End Sub

 

[JEC.]

Graag gedaan!:thumb:
@snb, werkt prima toch?