formule

[jvbaal]

Ik heb een werkmap met verschillende bladen.
Ik wil graag op het totaalblad een eindoverzicht krijgen.
Met de formule die ik gemaakt heb zou de computer op al de bladen (dagen van de week tot en met woensdag) moeten gaan kijken of er een codenummer in voor komt en zoja dan het resultaatgeven anders moet hij niets geven. De gebieden op de bladen hebben een naam gekregen en wel de dag van de week.
De computer geeft niet het juiste resultaat
Wat heb ik fout gedaan?

=ALS(isnb(OF(VERT.ZOEKEN($A2;maandag;2;0);VERT.ZOEKEN($A2;dinsdag;2;0);VERT.ZOEKEN($A2;woensdag;2;0)));"";OF(VERT.ZOEKEN($A2;maandag;2;0);VERT.ZOEKEN($A2;dinsdag;2;0);VERT.ZOEKEN($A2;woensdag;2;0)))

Ik kan natuurlijk wel voor iedere dag een kolom maken met een resultaat, maar dat is niet de bedoeling. Ik wilde het terug brengen naar een formule.
Overigens als ik onderstaande formule gebruik, dus voor een dag dan lukt het wel. Maar hoe combineer ik nu de formule tot meerdere dagen?

=ALS(ISNB(VERT.ZOEKEN($A2;maandag;2;0));"";VERT.ZOEKEN($A2;maandag;2;0))

 

[verhoog]

Kun je het bestandje zippen en hier posten, dan wordt het misschien wat duidelijker. Ik snap nu niet helemaal hoe je je bladen hebt ingedeeld en wat er bijvoorbeeld in cel A2 staat.

 

[jvbaal]

model

Verhoog,

Hierbij een gedeelte van het bestand. In het blad Totaal in B2 staat de formule waarom het gaat.

groetjes
Juul

 

[verhoog]

Ik heb het bestandje bekeken, maar je miste nogal wat in de formule:

Excel snapt het woord "maandag" in de formule niet, je moet aangeven dat het om het tabblad maandag gaat. Dit doe je dmv een uitroepteken achter de naam van het blad in de formule te plaatsen.

Verder heeft de formule "verticaal zoeken" een bereik nodig op het tabblad, wederom volstaat de naam van het blad niet. Dus als je de formule wil laten zoeken op het blad maandag naar een bepaalde waarde, moet je aangeven waar die dat moet doen. Een formule verticaal zoeken komt er dan bijv zo uit te zien:

=vert.zoeken(A7;maandag!A1:B100;2;onwaar)

Het leek alsof je "enkele" formule wel werkte, omdat ie geen waarde gaf, maar dat was alleen maar omdat je ISNB gebruikte. Dat even voor de theorie, nu terug naar je probleempje.

Ik heb het opgelost met "geneste" formules, ofwel een formule in een formule. Klinkt wat ingewikkeld, maar je vraagt de formule het volgende te doen:

kijk in blad maandag of je de waarde kunt vinden, zo niet kijk dan in blad dinsdag of je m daar kunt vinden (genest), lukt dat ook niet, doe dan niets. In het voorbeeld van hierboven komt het er zo uit te zien, waarbij het rode deel de geneste formule is:

=als(isnb(vert.zoeken(a7;maandag!A1:B100;2;onwaar));als(isnb(vert.zoeken(A7;dinsdag!A1:B100;2;onwaar);"";vert.zoeken(A7;dinsdag!A1:B100;2;onwaar)) ;vert.zoeken(A7;maandag!A1:B100;2;onwaar)))

Ik heb ook nog een bestandje bijgevoegd waar je het kunt zien. Maar let wel op, als de waarde in blad maandag én blad dinsdag voorkomt, zal ie altijd de waarde van blad maandag geven!! Dubbele waarden wertk dus niet, hij geeft altijd de eerste die die tegenkomt. Succes ermee....

 

[jvbaal]

Heel hartelijk dank voor de snelle reactie.
Ik zal er eens mee aan de slag gaan en natuurlijk laten weten of het werkt.

Overigens de dagnamen die in de formule gebruikt zijn zijn niet de tabbladen maar verwijzen naar een gebied op dat blad. Dus gebiedsnamen.

groetjes
juul

 

[verhoog]

Gebiedsnamen?? Interessant, kan je daar eens wat uitleg over geven, ken ik niet.

 

[Ingrid B]

Geplaatst door verhoog
Gebiedsnamen?? Interessant, kan je daar eens wat uitleg over geven, ken ik niet.

http://users.pandora.be/ingrid/excel/namen.htm

 

[Ingrid B]

Formule in B2:

=ALS(ISFOUT(VERT.ZOEKEN($A2;maandag;KOLOM();0));ALS(ISFOUT(VERT.ZOEKEN($A2;dinsdag;KOLOM();0));ALS(ISFOUT(VERT.ZOEKEN($A2;woensdag;KOLOM();0));"";VERT.ZOEKEN($A2;woensdag;KOLOM();0));VERT.ZOEKEN($A2;dinsdag;KOLOM();0));VERT.ZOEKEN($A2;maandag;KOLOM();0))

Deze formule kan je kopiëren naar de kolommen C, D en E zonder nog een aanpassing er aan te moeten doen.

 

[jvbaal]

Ingrid,

Heel hartelijk dank voor je oplossing.

Ik ben er achter gekomen dat het van belang is dat je in eerste instantie vanaf maandag begint en in het laatste gedeelte met woensdag begint. Waarom moet dit?
Als ik dat niet doe gaat het namelijk fout.

groetjes
juul

 

[Ingrid B]

Als je de formule uitschrijft als een programma wordt het misschien duidelijker:

=ALS(
    ISFOUT(VERT.ZOEKEN($A2;maandag;KOLOM();0));
    ALS(
        ISFOUT(VERT.ZOEKEN($A2;dinsdag;KOLOM();0))
        ;ALS(
            ISFOUT(VERT.ZOEKEN($A2;woensdag;KOLOM();0))
            ;""
            ;VERT.ZOEKEN($A2;woensdag;KOLOM();0))
        ;VERT.ZOEKEN($A2;dinsdag;KOLOM();0))
    ;VERT.ZOEKEN($A2;maandag;KOLOM();0)
)

Zo kan je beter zien welk ONWAAR-gedeelte bij welke zoekactie hoort.

 

[jvbaal]

Ingrid,
Bedankt voor de uitleg, zo worden we toch weer iedere dag wijzer.

groetjes
Juul