Geavanceerd filteren

[Jos12345]

Beste Excel-experts,

Ik zoek een oplossing voor het volgende (zie bijlage voor het voorbeeld).

Keuze land invullen via lijst in Cel B2.

Vervolgens moet de tabel zo gefilterd worden dat ik alleen de Vraag en Antwoord zie van betreffende land weergegeven met een x. Vb. bij selecteren Engeland wil ik alleen Vraag 1 en Antwoord 1 zien (oftewel lege cellen eruit gefilterd).

Bij voorbaat dank.

Vr. groet
Jos

 

[JEC.]

Office 365 vereist

=FILTER(B5:B18;FILTER(C5:F18;C4:F4=B2)="x")

 

[HSV]

Filter is vanaf Excel 2019 @JEC,


Hetzelfde resultaat met.

=FILTER(B5:B18;XLOOKUP(B2;C4:F4;C5:F18)="x")

XLOOKUP = X.ZOEKEN

 

[Jos12345]

@JEC, @HSV,

Heel erg bedankt!

Alle vragen en antwoorden komen nu onder elkaar. Is het mogelijk de lege rij te behouden, zie in mijn bijlage voorbeeld rij 9 en rij 14.

Bij voorbaat dank!

Vr, groet
Jos

 

[JEC.]

=TEXT(FILTER(B5:B18;(FILTER(C5:F18;C4:F4=B2)="x")+(B5:B18=""));"0;;")

 

[Jos12345]

@JEC, wederom veel dank!

Bij mijn voorbeeld: nu zie je bij 'Duitsland' 2 lege rijen komen, dat staat niet netjes in het resultaat. Is de formule nog zo aan te passen dat er maximaal 1 lege rij komt in het resultaat?

Wederom bij voorbaat dank!

 

[JEC.]

In je voorbeeld bestand gaat onderstaande niet goed. Ik neem even aan dat alle antwoorden in je echte bestand uniek zijn qua tekst.

=TEXT(UNIQUE(FILTER(B5:B18;(FILTER(C5:F18;C4:F4=B2)="x")+(B5:B18="")));"0;;")

 

[Jos12345]

Klopt @JEC, zie nieuw voorbeeld in de bijlage met antwoord 1 t/m 9.

Duitsland gaat goed nu. Alleen bij deze formule mist bij Belgie dan weer de lege regel.

Is het ook nog mogelijk dat de opmaak van de cel meegenomen wordt in het resultaat?

 

[JEC.]

Opmaak kan niet worden meegenomen vanuit een formule.

Dit werkt in ieder geval

=LET(r;FILTER(B5:B18;(FILTER(C5:F18;C4:F4=B2)="x"));DROP(REDUCE("";r;LAMBDA(a;b;VSTACK(a;IF(MOD(MATCH(b;r;0);2)=0;VSTACK(b;"");b))));1))

 

[Jos12345]

Veel dank! Heb draadje afgesloten!

Fijne dag @JEC

 

[JEC.]

Graag gedaan, van hetzelfde!