Geldigheid controleren

[WIMLIN]

Wie kan mij helpen om de geldigheid te controleren van document op datum. In het excel bestand is dit duidelijk weergegeven.

nr naam Documentsoort Geldig van Geldig tot
WN1 Piet A 1-1-2012 31-3-2012
WN1 Piet A 1-6-2012 30-6-2012

Doel te komen tot: een lijst die in de kolom Geldig Ja Nee automatisch een 1 geeft als het document geldig is.

Naam Datum Geldig JA Nee
Piet 1-1-2012 1
Piet 2-1-2012 1
Piet 3-1-2012 1
Piet 4-1-2012 1
Piet 1-4-2012

 

[pasan]

plaats deze formule in (N8) en trek naar beneden

=ALS(EN(M8>=$G$8;M8<=$H$8);1;ALS(EN(M8>=$G$9;M8<=$H$9);1;""))

 

[WIMLIN]

formule

Maar hoe weet deze formule als er een nieuwe medewerker is. Nu staan er bij piet maar twee regels zijn. Maar dit kunnen er ook wel 10 zijn. Kortom voor mij echt een super lastige klus. Ik moet 1500 medewerkers langs. Handmatig bijna niet te doen.

 

[pasan]

Plaats een voorbeeld zoals je werkelijk bedoeld maar dan met fictive namen

 

[Thankyou]

Zo ?

=SOMPRODUCT(($E$8:$E$28=$L8)*($G$8:$G$28<=$M8)*($H$8:$H$28>=$M8))

Of een kleine variant (maakt het uitlezen wat gemakkelijker)

=KIEZEN(SOMPRODUCT(($E$8:$E$28=$L8)*($G$8:$G$28<=$M8)*($H$8:$H$28>=$M8))+1;"Nee";"Ja")

Beide voor in N8, bereiken zelf aanpassen of met naambereiken werken

Succes,

 

[WHER]

Met Sumproduct moet dat lukken.

 

[WIMLIN]

Met de formule Somproduct is het nu gelukt. Maar nu zoek ik nog naar een mogelijkheid om de laatste geldigheid te tonen.

Bijvoorbeeld Piet heeft 4 document soorten A hoe kan ik degene vinden met de hoogste geldigheids datum.

 

[WIMLIN]

Hoe kan ik ook nog controleren wat er binnen een reeks van 120 dagen gebeurd

nr naam Documentsoort Geldig van Geldig tot
WN1 Piet A 1-1-2012 31-3-2012
WN1 Piet A 1-6-2012 30-6-2012
WN2 Jef B 1-4-2012 31-12-2012
WN3 Dirk A 1-1-2012 26-9-2012
WN4 Wim A 1-1-2012 27-9-2012






-90 30
27-8-2012 29-5-2012 26-9-2012

Als Geldigheid verloopt 90 dagen terug of binnen 30 dan een 1
Piet 1
Jef 0
Dirk 1
Wim 0

 

[Thankyou]

Zo ?

=ALS(SOMPRODUCT(($E$8:$E$12=S10)*($F$8:$F$12="A")*($H$8:$H$12>=$U$7)*($H$8:$H$12<=$V$7))>0;1;0)

Succes,

 

[Thankyou]

Of je gebruikt onderstaande matrix formule:

=ALS.FOUT(ALS(EN(GROOTSTE(ALS($E$8:$E$12&$F$8:$F$12=S10&"A";$H$8:$H$12);1)>=VANDAAG()-90;GROOTSTE(ALS($E$8:$E$12&$F$8:$F$12=S10&"A";$H$8:$H$12);1)<=VANDAAG()+30);1;0);"")

en afsluiten met CTRL+SHIFT+ENTER i.p.v. enter. Excel zet dan zelf de accolades { en } om de formule heen.

Een andere mogelijkheid is nog dat je in S10 : S14 alleen dit gedeelte zet :

=ALS.FOUT(GROOTSTE(ALS($E$8:$E$12&$F$8:$F$12=S10&"A";$H$8:$H$12);1);"")

(Ook Matrix-formule) en dan via VW-Opmaak een kleurtje mee geeft dmv deze formule:

=EN(VANDAAG()+30>=T10;VANDAAG()-90<=T10)

Nogmaals succes

 

[WIMLIN]

Formules

Martin,

Het duizelt mij wel even van de formules maar ik hoop morgen op mijn werk weer tijd te hebben om deze formules toe te passen.

Ik hoop dat het gaat lukken.

Groet,
Wim

 

[Thankyou]

In je testbestand werken ze.

Bij de somproduct furmule van post #9 kan je de verwijzingen naar de cellen U7 en V7 natuurlijk ook vervangen voor VANDAAG()-90 en VANDAAG()+30
Ook bij de bovenste formule uit post #10 heb je geen hulpcel nodig.

Hou er wel rekening mee dat veel matrix formules met een groot bereik je bestand kunnen vertragen.
Bij een groter bestand kan je het dus beter bij de somproduct formule houden.


Succes morgen.

 

[WIMLIN]

Martin,

In mijn originele bestand staan er minstens 2000 regels in. Die de geldigheid in een ander tabblad op moeten halen met nog veel meer regels. Heeft u uw formules in een excel bestand gezet. Zou u dan als bijlage willen tonen.

Groet,
Wim
Sliedrecht

 

[Thankyou]

Buurman, (bijna)

Knippen en plakken . . .

Succes,