gemiddelde over de laatste 3 bepalingen

[wil79]

Hallo forummers,

Voor een analyse wil ik het gemiddelde berekenen over de gehele reeks bepalingen, maar ook over de laatste 3 bepalingen.
Nu ben ik, althans voor mn gevoel, al een heel eind in de richting, alleen loop ik tegen een laatste restpuntje aan.

Gemiddelde over de gehele reeks:
Dat kan naturrlijk gewoon met de AVERAGE functie, aangezien deze functie alleen naar getallen kijkt.

Gemiddelde over de laatste 3 bepalingen:
Daarvoor had ik bedacht om de volgende functie te gebruiken:

=AVERAGE(OFFSET(B1,COUNTA(B2:B11),0,-3))

Waar ik tegen aanloop is dat, als er een beapling in de reeks wordt overgeslagen, er een x wordt ingevuld.
Nu wil ik wel graag het gemiddelde berekend hebben over de laatste 3 bepalingen waarin getallen zijn ingevuld (de x'en moeten dus geskipped worden....)
In het bijgevoegde bestand zou ik in cel C16 in dit geval dus het getal 3.333 willen zien......

Wie weet daarvoor een oplossing ????

Alvast bedankt voor de oplossing(en)........

Bekijk bijlage bepaling.xlsx

 

[wil79]

Had inmiddels ook bedacht om de functie:

=AVERAGEIF(C2:C11,"<>*x*",(OFFSET(C1,COUNTA(C2:C11),0,-3)))

te gebruiken, maar dan geeft ie in cel C16 de waarde 2.2903, terwijl het gemiddelde zou moetn uitkomen op 3.3333.......
Dit is dus blijkbaar nog niet de oplossing.

 

[AlexCEL]

Mijn gevoel zegt dat dit nog wel wat korter kan maar deze doen volgens mij wel wat je wilt...

Voor C16 (gemiddelde over 3 laatste waarden):

[NL]
=(INDEX(C$2:C$11;GROOTSTE(ALS(ISGETAL(C$2:C$11);RIJ(C$2:C$11));1)-1)+INDEX(C$2:C$11;GROOTSTE(ALS(ISGETAL(C$2:C$11);RIJ(C$2:C$11));2)-1)+INDEX(C$2:C$11;GROOTSTE(ALS(ISGETAL(C$2:C$11);RIJ(C$2:C$11));3)-1))/3

[ENG]
=(INDEX(C$2:C$11,LARGE(IF(ISNUMBER(C$2:C$11),ROW(C$2:C$11)),1)-1)+INDEX(C$2:C$11,LARGE(IF(ISNUMBER(C$2:C$11),ROW(C$2:C$11)),2)-1)+INDEX(C$2:C$11,LARGE(IF(ISNUMBER(C$2:C$11),ROW(C$2:C$11)),3)-1))/3

En voor C17 (Standaarddeviatie):

[NL]
=STDEV.P(INDEX(C$2:C$11;GROOTSTE(ALS(ISGETAL(C$2:C$11);RIJ(C$2:C$11));1)-1);INDEX(C$2:C$11;GROOTSTE(ALS(ISGETAL(C$2:C$11);RIJ(C$2:C$11));2)-1);INDEX(C$2:C$11;GROOTSTE(ALS(ISGETAL(C$2:C$11);RIJ(C$2:C$11));3)-1))

[ENG]
=STDEV.P(INDEX(C$2:C$11,LARGE(IF(ISNUMBER(C$2:C$11),ROW(C$2:C$11)),1)-1),INDEX(C$2:C$11,LARGE(IF(ISNUMBER(C$2:C$11),ROW(C$2:C$11)),2)-1),INDEX(C$2:C$11,LARGE(IF(ISNUMBER(C$2:C$11),ROW(C$2:C$11)),3)-1))

Het betreft hier Matrix-functies, dus afsluiten met Control + Shift + Enter.

 

[E v R]

afsluiten met CSE:

=AVERAGE(OFFSET($C$11;;;-ROW($C$11)-1+LARGE(ISNUMBER($C$2:$C$11)*ROW($C$2:$C$11);3)))