Getal links en rechts verticaal zoeken in een kolom

[huppelpaard]

Ik probeer in een rij waarbij het getal gescheiden is met een - (bijvoorbeeld 1-12), zowel de 1 als de 12 verticaal op te zoeken.
1-12 is maar een voorbeeld dit kan ook 11-22 / 99-101 / 1-6 zijn...... maar nooit meer dan 3 getallen.

nu heb ik meerdere mogelijkheden geprobeerd maar stuit nog op problemen.
Ik heb altijd 1 of meerdere hulp kolommen nodig om mijn doel te halen daarnaast krijg ik een foutmelding met de formule

=VERT.ZOEKEN(INDIRECT("c2");H:I;2;ONWAAR)

waarbij c2 gevuld is met een formule

ik meende dat dit ook te maken had met cel eigenschappen (tekst/getal) echter bij het aanpassen van de cel eigenschappen gebeurt er niks.

Kan iemand mij uitleggen of het mogelijk is om zonder hulp kolommen dit voor elkaar te krijgen?
en wat mijn fout is mbt verticaal zoeken.

Alvast bedankt

 

[edmoor]

Zo misschien?

 

[huppelpaard]

Bedankt voor je aanvulling

tot 99 gaat dat goed boven de 100 niet meer.
logisch want er worden maar 2 tekens verwacht in de formule. als ik deze verander naar 3 tekens gaat de 100 getallen wel weer goed maar 1-9 niet meer.


weet je toevallig ook waarom het fout gaat met verticaal zoeken?

 

[JEC.]

Welke Excel versie heb je? Dit zou moeten werken vanaf versie 2013

In E2, doortrekken naar F2 en naar beneden. Deze moet je als het goed is afsluiten met ctrl+shift+enter

=VLOOKUP(FILTERXML("<x><y>"&SUBSTITUTE($A2;"-";"</y><y>")&"</y></x>";"//y["&COLUMN(A1) & "]");$H$2:$I$25;2;0)

 

[huppelpaard]

hoi Jec

=VERT.ZOEKEN(XML.FILTEREN("<x><y>"&SUBSTITUEREN($A2;"-";"</y><y>")&"</y></x>";"//y["&KOLOM(A1) & "]");$H$2:$I$25;2;0)

geeft mij idd de 1e waarde van bijv 1-12 maar hoe zit het dan met de 12 als ik die ook op wilt zoeken?

 

[JEC.]

De formule naar rechts trekken zou moeten werken. Zie mijn vorige post.

 

[huppelpaard]

top dit werkt super ga mij eens verdiepen in xml formule dank je wel

 

[JEC.]

Mooizo, succes!

 

[huppelpaard]

nog iets uitgebreid
stel gevonden zoekwaarde links en gevonden zoekwaarde rechts 2 verschillende getallen zijn..... zoniet dan alsnog 1 zoekwaarde retourneren.

=ALS(VERT.ZOEKEN(XML.FILTEREN("<x><y>"&SUBSTITUEREN($A2;"-";"</y><y>")&"</y></x>";"//y["&KOLOM(A1) & "]");$H$2:$I$25;2;0)=VERT.ZOEKEN(XML.FILTEREN("<x><y>"&SUBSTITUEREN($A2;"-";"</y><y>")&"</y></x>";"//y["&KOLOM(B1) & "]");$H$2:$I$25;2;0);VERT.ZOEKEN(XML.FILTEREN("<x><y>"&SUBSTITUEREN($A2;"-";"</y><y>")&"</y></x>";"//y["&KOLOM(A1) & "]");$H$2:$I$25;2;0);VERT.ZOEKEN(XML.FILTEREN("<x><y>"&SUBSTITUEREN($A2;"-";"</y><y>")&"</y></x>";"//y["&KOLOM(A1) & "]");$H$2:$I$25;2;0)&"-"&VERT.ZOEKEN(XML.FILTEREN("<x><y>"&SUBSTITUEREN($A2;"-";"</y><y>")&"</y></x>";"//y["&KOLOM(B1) & "]");$H$2:$I$25;2;0))

 

[popipipo]

Hier een andere oplossing.
Omdat er een regelmaat zit tussen 'vergelijken' en 'resultaat' in dit voorbeeld hoef je niet vert.zoeken te gebruiken maar kan het ook met een formule in dit geval bv:

=Roundup(K2/4;0)
=ROUNDUP(IF(ISNUMBER(FIND("-"; A2)); LEFT(A2; FIND("-";A2)-1);A2)/4;0)
=ROUNDUP(IF(ISNUMBER(FIND("-"; A2)); RIGHT(A2;LEN(A2)- FIND("-";A2));A2)/4;0)

of als er geen regelmaat in zit:

=VLOOKUP(IF(ISNUMBER(FIND("-"; A2)); LEFT(A2; FIND("-";A2)-1);A2)*1;K2:L25;2;0)
=VLOOKUP(IF(ISNUMBER(FIND("-"; A2)); RIGHT(A2;LEN(A2)- FIND("-";A2));A2)*1;K2:L25;2;0)

 

[huppelpaard]

dank je wel deze benadering ga ik ook even verder op induiken het werkt zeker wel voor wat ik nodig heb.

ga ze eens opslaan voor toekomstige projectjes hier kan ik weer van leren :thumb:

allemaal enorm bedankt:thumb: