Hoe kan ik een excel bestand omzetten in een jpg

[visje12345]

Ik heb iets in excel gemaakt wat ik om wil zetten in een jpg bestand, echter krijg ik die optie in excel 2007 niet te zien!
Ik heb al op google gezocht, maar wat men daar aanbiedt, werkt niet (downloadprogramma).
Wie wil en kan mij helpen?

Enorm bedankt alvast voor je reactie.
Gr. Sanne

 

[huijb]

Maak een printscreen(Alt+Printscreen) en sla het op als jpg.

 

[Cobbe]

Je kunt toch een werkblad opslaan als PDF-bestand.
Anders neem je van elk werkblad een Printscreen, dan heb je je JPG-bestand.

 

[Niels28]

sla het bestand op als PDF.
Als je perse een JPG wilt hebben kun je dan eventueel een momentopname maken en die in paint plakken.

Dit doe je door in acrobatreader bij opties => selecteren en zoomen => moment opname
met ctrl-A selecteer je alles en kun je het in paint plakken en opslaan als jpg.

Niels

 

[jolivanes]

Can you adapt this?
Zet beiden in een normale Module.

Function ExportRangeToPicture(rng As Excel.Range, img As String) As Boolean
' save a range from Excel as a picture
' rng = Range to export
' img = filename & path

' basic error checking
' check for valid filetypes
' from http://peltiertech.com/WordPress/export-chart-as-image-file/
Const FILE_EXT As String = "gif,png,jpg,jpe,jpeg"
If InStr(FILE_EXT, LCase$(Right$(img, 3))) = 0 Then
  GoTo ExitProc
End If

' check for valid path
Dim path As String
path = Left$(img, InStrRev(img, "\"))
If Dir(path, vbDirectory) = "" Then GoTo ExitProc

' check for valid range
Dim rRng As Excel.Range
On Error Resume Next
Set rRng = rng   '.CurrentRegion
On Error GoTo 0
If rRng Is Nothing Then GoTo ExitProc

' check for protected worksheet
If ActiveSheet.ProtectContents Then GoTo ExitProc

' copy range to picture, put into chart, export it
Application.ScreenUpdating = False
rRng.CopyPicture xlScreen, xlPicture

Dim cht As Excel.ChartObject
Set cht = ActiveSheet.ChartObjects.Add(0, 0, rng.Width + 10, rng.Height + 10)

With cht
  .Chart.Paste
  .Chart.Export img
  .Delete
End With

' if we got this far, assume success
ExportRangeToPicture = True

ExitProc:
Application.ScreenUpdating = True
Set cht = Nothing
Set rRng = Nothing
End Function
'There's some basic error checking, such as checking for valid image file extension and valid ranges. _
It also makes sure the worksheet isn't protected, because we're adding worksheet objects (temporarily).

Sub test()
Dim rng As Excel.Range
Set rng = Selection  'Range("A1:A47") <------- een van beiden

If ExportRangeToPicture(rng, "C:\range.jpg") Then   'jpg, gif of png extension
  MsgBox "Het is gelukt!"
Else
  MsgBox "Mislukt!"
End If
End Sub

HTH

John

 

[jolivanes]

Hier is er nog een.

' DateTime  : 05/03/2007 13:59
 ' Author    : Roy Cox (royUK)
 ' Website   : www.excel-it.com] more examples
 ' Purpose   : Copy a  range as a picture
 ' Disclaimer; This code is offered as is with no guarantees. You may use it in your
 '             projects but please leave this  header intact.
 '---------------------------------------------------------------------------------------
Option Explicit
Sub paste_Picture()
    Application.ScreenUpdating = True
    Dim UserRange As Range
    Dim OutputRange As Range
    Dim MyPrompt As String
    Dim MyTitle As String
     'Prompt user for range to capture
    MyPrompt = "Select the range you would like to capture."
    MyTitle = "User Input Required"
    On Error Resume Next
    Set UserRange = Application.InputBox(Prompt:=MyPrompt, _
    Title:=MyTitle, Default:=ActiveCell.Address, Type:=8)
    If UserRange Is Nothing Then End
    On Error GoTo 0
     
     'Copy range to Clipboard as picture
    UserRange.CopyPicture
     
     'Prompt user for range to paste to
    MyPrompt = "Select the range on which you would like to paste."
    MyTitle = "User Input Required"
    On Error Resume Next
    Set OutputRange = Application.InputBox(Prompt:=MyPrompt, _
    Title:=MyTitle, Default:=ActiveCell.Address, Type:=8)
    If OutputRange Is Nothing Then End
    On Error GoTo 0
     
     'Paste picture to output range
    OutputRange.PasteSpecial
    'Selection.Formula = UserRange.Address
End Sub

HTH

John

 

[robdgr]

En de camera?