Horizontaal zoeken meerdere kolomen

[bkoppers]

Goede morgen,

Wellicht dat iemand mij kan helpen.
Ik heb een tabel en zoek een bepaalde waarde (staat in A15) deze te zoeken waarde staat in het bereik van kolom E t/m J, nu zou ik graag zien dat de waarde uit kolom A wordt weergegeven in cel A16.

alvast bedankt.Bekijk bijlage Horizontaal zoeken meerdere kolomen.xlsm

 

[Peter B]

Ik zou het zo oplossen:

=IFERROR(INDEX(Tabel1[Kolom1];MATCH(A15;Tabel1[Kolom5];0));IFERROR(INDEX(Tabel1[Kolom1];MATCH(A15;Tabel1[Kolom6];0));IFERROR(INDEX(Tabel1[Kolom1];MATCH(A15;Tabel1[Kolom7];0));IFERROR(INDEX(Tabel1[Kolom1];MATCH(A15;Tabel1[Kolom8];0));IFERROR(INDEX(Tabel1[Kolom1];MATCH(A15;Tabel1[Kolom9];0));IFERROR(INDEX(Tabel1[Kolom1];MATCH(A15;Tabel1[Kolom10];0));""))))))

Ik zeg niet dat dit de oplossing is, maar het werkt ...

 

[bkoppers]

Bedankt voor je reactie, echter ik zou graag een kortere oplossing zien. als die überhaupt bestaat

 

[Peter B]

Ik vond 'm wel interessant. En heb een kortere formule voor je gevonden ...

=INDEX(A2:A9;SUMPRODUCT((E2:J9=A15)*(ROW(1:8))))

 

[plongske]

@Peter
Goed gevonden:thumb:
Werkt helaas niet bij uitbreiding van de tabel.(toch niet bij mij)
Daarom heb ik even verder gezocht en kom ik tot deze oplossing

=INDEX(A2:A9;SOMPRODUCT((E2:J9=A14)*AANTALARG(Tabel1[Kolom1])))

Bedankt alvast voor de voorzet

 

[AlexCEL]

Plongske, die van jou gaat niet goed volgens mij . De formule zal altijd de laatste waarde van de tabel geven!

De RIJ(1:8) is juist de bedoeld om via de INDEX de juiste rij op te zoeken...

Als je het echt flexibel wilt maken moet je volgens mij aan zoiets denken:

=INDEX(Tabel1[Kolom1];SOMPRODUCT((E2:J10=A15)*RIJ(INDIRECT("1:"&AANTALARG(Tabel1[Kolom1]))))-1)

 

[Peter B]

Samen met AlexCEL's formule kom ik dan tot de volgende (echt) flexibele oplossing. Wel moet bij uitbreiden van de tabel altijd gezorgd worden dat er geen lege waarden staan in kolom A:

=INDEX(Tabel1[Kolom1];SUMPRODUCT((Tabel1[#Data]=$A$15)*ROW(INDIRECT("1:"&COUNTA(Tabel1[Kolom1])))))

 

[bkoppers]

:thumb:
allemaal bedankt voor het meedenken de oplossing van PeterB werkt prima voor mij, super bedankt allemaal.

 

[tkint]

@ Perer B en bkoppers,

Bij mij (versie 2007) geeft deze formule een foutmelding :=INDEX(Tabel1[Kolom1];SUMPRODUCT((Tabel1[#Data]=$A$15)*ROW(INDIRECT("1:"&COUNTA(Tabel1[Kolom1])))))
Ik heb ze wel vertaald naar het Nederlands. Zou de fout veroorzaakt worden door [#Data]?

 

[Peter B]

Heb je hem volledig vertaald? Bv. via de link in mijn ondertekening? Een veel gemaakte fout is SUMPRODUCT <> SOMPRODUCT

 

[tkint]

Beste,

Ik heb jouw formule als volgt vertaald :=INDEX(Tabel1[Kolom1];SOMPRODUCT((Tabel1[#Data]=$A$15)*RIJ(INDIRECT("1:"&AANTALARG(Tabel1[Kolom1]))))).
Rode tekst=fout

 

[VenA]

Maak er eens dit van.

=INDEX(Tabel1[Kolom1];SOMPRODUCT((Tabel1=$A$15)*RIJ(INDIRECT("1:"&AANTALARG(Tabel1[Kolom1])))))

 

[AlexCEL]

We komen er wel :thumb:

 

[tkint]

Beste,

Met de aanpassingen van VenA functioneert de formule. Bedankt.

 

[VenA]

We komen er wel :thumb:

Het denkwerk komt van jou en Peter B. Even op <F2> drukken en een kleine aanpassing doen lukt mij meestal wel:d


@Peter B,
Zowel in Xl-2010 En en Xl-2007 Nl krijg ik bij het selecteren van de 'databodyrange' 'Tabel1' als resultaat in de formule.
Waar haal jij Tabel1[#Data] vandaan. Bewust ingetoetst of een nieuwere versie van XL dan XL-2010 waarbij dit automatisch gebeurt bij het selecteren van de 'databodyrange'?


Om het draadje te comleteren

=INDEX(Tabel1[Kolom1];SUMPRODUCT((Tabel1[#Data]=$A$15)*ROW(INDIRECT("1:"&COUNTA(Tabel1[Kolom1])))))
=INDEX(Tabel1[Kolom1];SUMPRODUCT((Tabel1=$A$15)*ROW(INDIRECT("1:"&COUNTA(Tabel1[Kolom1])))))

=INDEX(Tabel1[Kolom1];SOMPRODUCT((Tabel1[#Gegevens]=$A$15)*RIJ(INDIRECT("1:"&AANTALARG(Tabel1[Kolom1])))))
=INDEX(Tabel1[Kolom1];SOMPRODUCT((Tabel1=$A$15)*RIJ(INDIRECT("1:"&AANTALARG(Tabel1[Kolom1])))))

 

[Peter B]

Dat is een gewetensvraag ... Ik denk idd. door selecteren van de data (in Excel 2013).

Als ik =Tabel1[# ingeef dan krijg ik de volgende opties:
#All
#Data
#Headers
#Totals

 

[VenA]

Dat is een gewetensvraag ...

Was ook weer niet de bedoeling:d

Bedankt voor jouw antwoord.

 

[plongske]

Was even aan het volgen en heb toch weer bij geleerd ivb met tabellen.
bedankt Peter

 

[puppie]

op verzoek heropend.

 

[Ginger]

op verzoek heropend.

Dan nu maar afwachten wat de vraag gaat worden? Is een nieuwe vraag met een verwijzing naar dit draadje niet véél eenvoudiger???