Hulp bij aanpassing script om inbox outlook uit te lezen.

[kmk]

Beste mensen,

Een tijd terug vond ik dit fantastische exceldocumentje in een van postings. Het werkt allemaal prima, maar…

Er is altijd een maar, ik wil er graag nog meer mee en wel het volgende:
Op mijn werk hebben we Outlook 2003 waar ik zowel mijn eigen inbox heb waar dit script prima mee overweg kan en een andere mailbox die ik beheer voor mijn team. Nu wil ik graag dat dit script een overzicht laat zien van die betreffende inbox. Die van het team dus! Het mooiste zou ook nog zijn als mbv dit script ook de submapjes kunnen worden ingelezen en worden verwerkt.

Wie kan mij helpen door aanpassing van dit script? Zelf heb ik er niet heel veel verstand van en met proberen en zoeken kom ik er ook niet uit. Ik weet dus ook niet of mijn wensen wel mogelijk zijn.

Groeten

Kmk

 

[snb]

Dat kan simpeler en sneller:

Sub Inmail_in_Excel()
  With Outlook.GetNamespace("MAPI").GetDefaultFolder(6)
    ReDim sq(.Items.Count, 5)
    For j = 1 To UBound(sq)
      With .Items(j)
        For jj = 1 To UBound(sq, 2)
          sq(j - 1, jj - 1) = Choose(jj, .Subject, Format(.ReceivedTime, "dd-mm-yyyy hh:mm"), .SenderName, .Attachments.Count, IIf(.UnRead, "N", "J"))
        Next
      End With
    Next
  End With
  With Sheets.Add
    .Cells(2, 1).Resize(UBound(sq), UBound(sq, 2)) = sq
    With .Cells(1, 1).Resize(, 5)
      .Value = Split("Onderwerp|Ontvangen|Van|Bijlagen|Gelezen", "|")
      .Font.Bold = True
      .Font.Size = 14
    End With
    .Columns("A:E").AutoFit
  End With
End Sub

Je vraag naar de ander InBox kan alleen beantwoord worden als je een overzicht geeft van je outlook mappenstruktuur.
Voorbeeld:
Outlook.GetNamespace("MAPI").GetDefaultFolder(6) is hetzelfde als
Outlook.GetNamespace("MAPI").folders("Postvak In")

Als je meeer accounts hebt wordt het wat gecompliceerder.

 

[kmk]

vervolg

Kijk, dat is al heel mooi. Bedankt!

Ik ga even de structuur na. Ik zal dit zsm posten.

Groeten

Kmk

 

[kmk]

het duurde even, maar dan nu toch ;-)

Excuus dat het even duurde, ik zal hier zo volledig mogelijk een overzicht proberen te geven van de mappenstructuur zoals aanwezig op het werk.

- Postvak - (naam1)
deleted items
Drafts
Inbox
submap1
submap2
Infected
ongewenste email
Outbox
Quarantine
Sent Items
+Zoekmappen
+Archiefmappen
- Postvak (Naam2)
Submap1
Inbox
Submap2
--------------------------------------------------------------------------------------------------------------------------
Het draait dus om Postvak(naam2), die wil ik graag uitlezen
ipv inbox van Postvak(naam1), of evt een keuze kunnen
maken. Ik kan helaas geen screenprint maken ivm vertrouwelijke info van het werk.

Dank alvast voor de hulp!

 

[snb]

Sub Inmail_in_Excel()
With Outlook.GetNamespace("MAPI").Folders("Postvak (naam2)").Folders("Postvak IN")

Omdat je te summier bent met je informatie moet je de blauwe tekst zelf nog aanpassen.

 

[kmk]

Gelukt!!

Dank SNB!!

het is gelukt. Een klein vraagje nog, kan ik ook meerdere folders uitlezen en deze dan samenvoegen op een blad? Ik ben zelf al even aan het proberen geslagen, maar dan is het resultaat 'slechts' 1 folder die lukt.

Weer bedankt voor je hulp!!

Grtz

KmK

 

[snb]

Voorbeeld:

Sub Inmail_in_Excel()
  With Sheets.Add
    With .Cells(1, 1).Resize(, 5)
      .Value = Split("Onderwerp|Ontvangen|Van|Bijlagen|Gelezen", "|")
      .Font.Bold = True
      .Font.Size = 14
    End With
    [COLOR="Blue"]For Each fl in Outlook.GetNamespace("MAPI").Folders("Postvak (naam2)").Folders
       ReDim sq(fl.Items.Count, 5)
       For j = 1 To UBound(sq)
         With fl.Items(j)
           For jj = 1 To UBound(sq, 2)
             sq(j - 1, jj - 1) = Choose(jj, .Subject, Format(.ReceivedTime, "dd-mm-yyyy hh:mm"), .SenderName, .Attachments.Count, IIf(.UnRead, "N", "J"))
           Next
         End With
       Next
      .Cells(rows.count, 1).end(xlup).offset(1).Resize(UBound(sq), UBound(sq, 2)) = sq
    Next [/COLOR]
    .Columns("A:E").AutoFit
  End With
End Sub

 

[kmk]

helemaal geweldig!

Het is allemaal gelukt!

SNB, bedankt voor je hulp!:thumb:

Groeten

KMK