Opgelost hulp bij formule

[kibus]

beste Kenners

ik koop in verschillende partijen met verschillende inkoopprijzen, voor het gemak 1 artikel :

aantal / prijs
100 / 5
150 / 6
180 /7

als ik er 125 verkocht heb, dan heb ik nog 25 leggen tegen 6 en 180 tegen 7, nu koop ik verschillende artikelen zie bijlage dan zou het mooi zijn als ik de uitkomst in forumule zie in I5 en i6 enig idee, hoe ik dit zou kunnen doen met 1 formule zonder te sorteren ?

met vriendelijke groet kibus

 

[kibus]

beste Kenners

ik koop in verschillende partijen met verschillende inkoopprijzen, voor het gemak 1 artikel :

aantal / prijs
100 / 5
150 / 6
180 /7

als ik er 125 verkocht heb, dan heb ik nog 125 leggen tegen 6 en 180 tegen 7, nu koop ik verschillende artikelen zie bijlage dan zou het mooi zijn als ik de uitkomst in forumule zie in I5 en i6 enig idee, hoe ik dit zou kunnen doen met 1 formule zonder te sorteren ?

met vriendelijke groet kibus

 

[AlexCEL]

Waarom 2x hetzelfde bericht?

Ik heb iets vlot in elkaar gezet, misschien kan het eleganter maar geeft volgens mij wel de gewenste resultaten. Wel Excel 365 nodig.

=LET(a;A$5:A$14;b;B$5:B$14;ab;$A$5:$B$14;c;C$5:C$14;e;E5;f;F5;
x;ALS(a=e;SOM.ALS(INDIRECT("A5:A"&4+REEKS(RIJEN(a);1));e;b);"");
y;ALS(a=e;c);
z;FILTER(HOR.STAPELEN(x;y);x<>"");
VERT.ZOEKEN(f+VERT.ZOEKEN(E5;ab;2;0);z;2;WAAR))

 

[jverkerk]

@AlexCEL Dat je er nog wijs uit kan worden zo'n formule.

 

[AlexCEL]

De LET functie helpt daar enorm bij, omdat je alle afzonderlijke stapjes goed kunt volgen.

Ik heb wel het gevoel dat het simpeler kan, en ga er later dus nog eens naar kijken.

 

[AlexCEL]

Deze is al wat korter en eleganter.

=LET(a;A$5:A$14;b;B$5:B$14;ab;A$5:B$14;c;C$5:C$14;e;E5;f;F5;
z;HOR.STAPELEN(SCAN(0;FILTER(b;a=E5;"");LAMBDA(x;y;x+y));FILTER(c;a=e;""));
VERT.ZOEKEN(f+VERT.ZOEKEN(e;ab;2;0);z;2;WAAR))

Controleer s.v.p. of deze de gewenste uitkomsten geeft...

 

[kibus]

merci, Alexcel

nog niet helemaal

artikelcode / aantal / prijs
A / 100 / 5
B / 100 / 6
A / 25 / 6
A / 50 / 7
B / 100 / 6
B / 100 /5



van artikel A gaan er bv 115 af
dan heb ik nog leggen 10 tegen 6 en 50 tegen 7 uitkomst zou dan 6 moeten zijn
indien van A 135 af zou gaan dan is de uitkomst 40 tegen 7

artikel B indien er hier 200 afgaan zou de uitkomst moeten zijn 100 tegen 5
indien van B er 105 afgaan zou de uitkomst moeten zijn 95 tegen 6

enzv eigenlijk is het een soort stock/voorraad bepaling

 

[AlexCEL]

Ik heb de formule verder aangepast en volgens mij voldoet het daarmee aan je vraagstelling.

=LET(a;A$3:A$8=E3;INDEX(FILTER(C$3:C$8;a);1+VERGELIJKEN(F3;SCAN(0;FILTER(B$3:B$8;a);LAMBDA(x;y;x+y));1)))

Zie ook bijlage.

 

[kibus]

Geweldig super merci!