Hyperlink file list uitsluiten extensie werkt niet

[loek010]

Beste hulpverleners,

Ik heb een probleem met onderstaande code ik wil dus bepaalde files die in de map facturen staan zoals zip exe of ini
uitsluiten in de hyper file list dus dat hij allen maar .pdf links maakt alleen het werkt niet iemand eventueel een oplossing

Option Compare Text
Option Explicit
 
Function Excludes(Ext As String) As Boolean
     'Function purpose:  To exclude listed file extensions from hyperlink listing
     
    Dim X, NumPos As Long
     
     'Enter/adjust file extensions to EXCLUDE from listing here:
    X = Array("exe", "bat", "dll", "zip", "ini")
     
    On Error Resume Next
    NumPos = Application.WorksheetFunction.Match(Ext, X, 0)
    If NumPos > 0 Then Excludes = True
    On Error GoTo 0
     
End Function

Sub HyperlinkFileList()
Application.ScreenUpdating = False

Dim objFSO As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim i As Integer
     
    Set objFSO = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFSO.GetFolder("C:\Users\WP\Documents\Facturen")
    i = 1
    For Each objFile In objFolder.Files
      Sheets("Factuuroverzicht").Select
         
        Range(Cells(i + 1, 11), Cells(i + 1, 11)).Select
         
        ActiveSheet.Hyperlinks.Add Anchor:=Selection, Address:= _
        objFile.Path, _
        TextToDisplay:=objFile.Name
        i = i + 1
    Next objFile
    Range("A3").Select
    
    Application.ScreenUpdating = True
End Sub

Groet Loek010

 

[snb]

Haal de bestanden waarnaar geen snelkoppeling gemaakt mag worden uit de folder met bestanden waarnaar je een snelkoppeling wil maken.

Waarom staan daar überhaupt exe, zip of ini bestanden ????

 

[dnties]

Dim X, NumPos As Long

'Enter/adjust file extensions to EXCLUDE from listing here:
X = Array("exe", "bat", "dll", "zip", "ini")

Dat ziet er vreemd uit: Je declareert X als een LONG, maar je geeft het de waarde van een array met tekstelementen??
Geen idee of dat iets met je probleem te maken heeft, maar het lijkt me fout??

Tijs.

 

[edmoor]

De variabele X zal in dit geval een Variant zijn, niet een Long.

 

[wampier]

waar wordt de function "excludes" aangeroepen?

 

[loek010]

Beste hulpverleners

Bedankt voor jullie snelle reacties.

Antwoord aan snb is dat heb ik al gedaan in de map facturen door allen pdf files te plaatsen maar er blijft verborgen een desktop.ini
in de map staan die hij steeds meeneemt in de lijst vandaar dat stukje code wat ik gevonden heb op internet

Antwoord aan Edmoor long as variant werkt ook niet.

Antwoord aan wampier het probleem zal denk ik daar in zitten waar wordt de exclude optie aangesproken, allen zou ik niet weten
waar ik dat in de code zou moeten plaatsen

in ieder geval nog maals bedant voor jullie snelle reacties

Loek010

 

[edmoor]

Wat ik zei is dat als je een Dim van een variabele doet zonder een datatype mee te geven, deze als variant wordt gedeclareerd.
Het was een reactie op dnties en staat los van je probleem.

 

[edmoor]

Doe het eens zo:

Sub HyperlinkFileList()
    Dim objFSO As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim i As Integer
     
    Application.ScreenUpdating = False
    Set objFSO = CreateObject("Scripting.FileSystemObject")
    Set objFolder =objFSO.GetFolder("C:\Users\WP\Documents\Facturen")

    For Each objFile In objFolder.Files
        If Right(objFile.Name, 3) = "pdf" Then
            i = i + 1
            ActiveSheet.Hyperlinks.Add Anchor:=Sheets("Factuuroverzicht").Cells(i + 1, 11), _
                Address:=objFile.Path, TextToDisplay:=objFile.Name
        End If
    Next objFile
    Range("A3").Select
    
    Application.ScreenUpdating = True
End Sub

 

[loek010]

Beste Edmoor

Dat werkt deze code bedankt, dus had dat stukje code van excludes helemaal niet nodig.
soms kan het simpel zijn.
In ieder geval bedankt voor je inzet om met mij mee te denken.

Vriendelijke groet,
Loek010

PS zal de vraag op opgelost zetten.

 

[edmoor]

Graag gedaan

 

[snb]

Sub M_snb()
   sn=split(createobject("wscript.shell").exec("cmd /c dir C:\Users\WP\Documents\Facturen\*.pdf /b/s/a-d").stdout.readall,vbcrlf)
   
   for j=0 to ubound(sn)-1
      Sheets("Factuuroverzicht").Hyperlinks.Add Sheets("Factuuroverzicht").Cells(j + 1, 11), sn(j), dir(sn(j))
   Next
End Sub