Kleiner dan teken (<)

[Hendriks89]

Goedenavond,

Zit met het volgende probleem:

Heb twee waardes, waarvan één waarde met een kleiner dan (<) teken ervoor.

Nu wil ik in een lange formule dat teken niet meegenomen hebben, alleen de waarde zelf.

Hoe doe ik dat?

Natuurlijk moet het < teken wel in de cel blijven staan.

Graag zie ik jullie reactie spoedig tegemoet. Bij voorbaat dank!

Groeten,

Hendriks

Bekijk bijlage Voorbeeld.xlsx

 

[edmoor]

Kijk eens naar de functies DEEL() en/of VIND.SPEC()

 

[roeljongman]

of de substitueren() formule

 

[VenA]

Je kan beter even een voorbeedbestandje bijvoegen. Beide aangedragen oplossingen leveren een tekstwaarde op. En daar kan je in veel gevallen niet verder mee rekenen.

 

[Hendriks89]

Goedemorgen,

Allereerst dank voor de snelle reacties!

Zoals gevraagd, heb het voorbeeldbestandje toegevoegd.
Vragen staan ook in de sheet..

Mooiste is als iemand verbeteringen door kan voeren en het bestandje opnieuw kan uploaden.

Hoop dat iemand mij hiermee kan helpen, kom er namelijk echt niet uit!
Niet gek, mijn kennis is ook niet heel best op dit gebied.

Hoor graag van jullie!

Groeten,

Hendriks

 

[AlexCEL]

Ik kom uit op onderstaande formules:

Waarnemingen (cel D6 als vb): 
=ALS(EN(LINKS(B6;1)=TEKEN(60);LINKS(C6;1)=TEKEN(60));"<0,050";(SUBSTITUEREN(B6;"<";"")*ALS(LINKS(B6;1)=TEKEN(60);0,7;1)+SUBSTITUEREN(C6;"<";"")*ALS(LINKS(C6;1)=TEKEN(60);0,7;1))/2)

"log-getransformeerde waarneming" (cel Q6)
=LOG(ALS(ISGETAL(D6);D6;1)*ALS(ISGETAL(G6);G6;1)*ALS(ISGETAL(J6);J6;1)*ALS(ISGETAL(M6);M6;1)*ALS(ISGETAL(P6);P6;1))/5

Standaarddeviatie (cel R6):
=STDEV(ALS(ISGETAL(D6);LOG(D6);0);ALS(ISGETAL(G6);LOG(G6);0);ALS(ISGETAL(J6);LOG(J6);0);ALS(ISGETAL(M6);LOG(M6);0);ALS(ISGETAL(P6);LOG(P6);0))

Dit alles ingevuld in je voorbeeldbestand: Bekijk bijlage Voorbeeld (AC).xlsx

Update: ben nog een beetje aan hobbyen geweest. De laatste 2 formules kunnen nog wat korter eventueel.

=LOG(ALS.FOUT(1*D6;1)*ALS.FOUT(1*G6;1)*ALS.FOUT(1*J6;1)*ALS.FOUT(1*M6;1)*ALS.FOUT(1*P6;1))/5

=STDEV(ALS.FOUT(LOG(D6);0);ALS.FOUT(LOG(G6);0);ALS.FOUT(LOG(J6);0);ALS.FOUT(LOG(M6);0);ALS.FOUT(LOG(P6);0))

 

[Hendriks89]

Super bedankt Alex!

Als ik die formules zie kom ik erachter dat mij dat nooit was gelukt!

Alleen balen dat ik dit niet kan controleren, te moeilijk.

Kan iemand anders dat misschien? Of ben je zeker van je zaak?

Nogmaals dank!

 

[AlexCEL]

Reken een paar bekende sommen na met de formules zou ik zeggen....

 

[Hendriks89]

Heb 't even uitgetest..

Naar mijn idee kloppen de formules wel..

Alleen wanneer ik andere kleiner dan (<) waarde heb gaat het mis..

Bijvoorbeeld als het getal <0,003 is, dan moet ik deze handmatig aanpassen in de formule..

Of is daar ook een oplossing voor?

 

[AlexCEL]

Jawel, bijvoorbeeld zo:

=ALS(EN(LINKS(B6;1)=TEKEN(60);LINKS(C6;1)=TEKEN(60));B6;(SUBSTITUEREN(B6;"<";"")*ALS(LINKS(B6;1)=TEKEN(60);0,7;1)+SUBSTITUEREN(C6;"<";"")*ALS(LINKS(C6;1)=TEKEN(60);0,7;1))/2)

Vraag die bij me op komt is: wat is het gemiddelde als x1 <0,030, x2 <0,050 ?