kolomletter in formule verwerken

[oeldere]

Beste forumleden,

hoe kan de kolomkop (A of B) variabel in een formule gezet worden.

ik liep hier tegen aan bij beantwoording van deze vraag (#7)

zie hierhttp://www.helpmij.nl/forum/showthread.php/585217-verschillende-werkbladen-verschillende-problemen?p=3723921&viewfull=1#post3723921

in post #8 van die vaag heb ik dit nu opgelost door in rij 1 de kolomkoppen te herhalen.
dit lijkt mij toch ook anders te moeten kunnen.

=ALS(INDIRECT($B$4&"!"&A$1&RIJ()+($A$2-RIJ($A$6)))=0;"";INDIRECT($B$4&"!"&A$1&RIJ()+($A$2-RIJ($A$6))))

de celinhoud van A1 =A

weet iemand een oplossing?

heb je vragen, laat het gewoon even weten.

 

[danny147]

Beste oeldere

Al eens geprobeerd met de formule:

=ALS(INDIRECT(ADRES(...

Zal vanavond eens kijken, moet nu weg.

Groetjes Danny. :thumb:

 

[zapatr]

Uitgaande van de formule die je hierboven hebt geplaatst, is dit een (nogal lange) mogelijkheid:

=ALS(INDIRECT($B$4&"!"&SUBSTITUEREN(ADRES(1;KOLOM();4);"1";"")&RIJ()+($A$2-RIJ($A$6)))=0;"";INDIRECT($B$4&"!"&SUBSTITUEREN(ADRES(1;KOLOM();4);"1";"")&RIJ()+($A$2-RIJ($A$6))))

 

[danny147]

Beste oeldere

Plaats de volgende formule in cel B4 sleep naar rechts en dan naar beneden:

=ALS((INDIRECT(ADRES(RIJ()+6;KOLOM();;;$B$2))=0);" ";INDIRECT(ADRES(RIJ()+6;KOLOM();;;$B$2)))

Groetjes Danny. :thumb:

 

[oeldere]

@ zapatr

=SUBSTITUEREN(ADRES(1;KOLOM();4);"1";"")

deze code geeft de waarde van de kolom weer. Super :thumb::thumb:

@danny
jouw code geeft de waarde van de kolom weer. Super :thumb::thumb:
ik begrijp de code echter niet.
wil je daar nog een toelichting op geven?


zaptr
ik lees de code als volgt.

syntax

ADRES(rij_getal, kolom_getal, [abs_getal], [a1], [blad_tekst])

vervang van (rij 1, kolom, (4)met een relatieve verwijzing, (1) alfabetisch genummerd

waarom wordt de code afgesloten met "" (leeg)?

 

[zapatr]

oeldere,
dit

SUBSTITUEREN(ADRES(1;KOLOM();4);"1";"")

had ik inderdaad verwerkt in de formule die in het bestand waarnaar je verwees, in het eerste blad in A6 staat. Het vervangt in jouw formule A$1, B$1, C$1, enz.
Zoals je weet kan in plaats van A$1, als we de functie adres gebruiken, worden geschreven: =adres(1;1;2) en als we die functie willen kopiëren naar de kolommen rechts van kolom A, maken we daarvan: =adres(1;kolom();2) . Omdat ik zowel rij als kolom relatief wil, vervang ik de 2 door een een 4. We krijgen dan: =adres(1;kolom();4). Als die functie in kolom A staat, vertegenwoordigt ze het adres A1, in kolom B: B1, enz. Omdat ik alleen geïinteresseerd ben in de kolomletter, laat ik de 1 vervallen, die vervang ik met substitueren door niets(""). Alleen de kolomletter blijft dan over, en dat is wat ik wou. En door het adres volledig relatief te maken, hoeft alleen het rijnummer worden vervangen. Je begrijpt nu waarschijnlijk ook wel dat ik in plaats van adres(1;kolom();4);"") bv. ook had kunnen schrijven: adres(274;kolom();4), maar dan had ik in de substitutieformule in plaats van 1 het getal 274 moeten vervangen. Dat had dan (beginnend met de formule in kolom A) hetzelfde resultaat opgeleverd, namelijk de gewenste kolomletter. De letters die in in het eerste blad in rij 1 staan, kunnen dus worden verwijderd. Duidelijk zo? Indien ja, wil je dan de vraag als "opgelost" markeren a.u.b.?

 

[danny147]

Beste oeldere

=oeldere;3725451

@danny
jouw code geeft de waarde van de kolom weer. Super :thumb::thumb:
ik begrijp de code echter niet.
wil je daar nog een toelichting op geven?

Je moet dus zoeken naar cel B10 op Blad Confectionery

syntax code :

ADRES(rij_getal, kolom_getal, [abs_getal], [a1], [blad_tekst])

ADRES(RIJ()+6;KOLOM();;;$B$2)

RIJ is daar waar de formule moet inkomen en het verschil van rij erbij tellen tot B10
in dit geval is dit cel B4 + 6 bijtellen

Voor Kolom blijft dit hetzelfde B 4 en B 10 dus KOLOM()

Niks voor [abs_getal] en [a1] dus ;;

Voor [blad_tekst] wordt er verwezen naar Cel B2.

Groetjes Danny. :thumb:

 

[oeldere]

kolomletter zoeken

@zapatr

 laat ik de 1 vervallen, die vervang ik met substitueren door niets("")

met deze toelichting ben ik super geholpen. :thumb: (applaus).

@danny

Niks voor [abs_getal] en [a1] dus ;;

met deze toelichting ben ik super geholpen. :thumb: (applaus).

ik zet de vraag nu op opgelost