Lege regel selecteren op basis van kolom A tm F

[Rob532]

In excel wil ik via VBA de eerste lege regel selecteren op basis van kolom A tm F.
Ik wil dan iets wegschrijven in kolom A.
Maar ik wil ook weten hoe ik iets weg kan schrijven in kolom B of C.
Ik gebruik nu:
Range("A" & Rows.Count).End(xlUp).Offset(1).Select
ActiveCell = "**Vergaderen"

Deze formule kijkt alleen naar Kolom A.
Wie weet een oplossing?

Bedankt alvast

 

[HSV]

Lukt het hiermee? of staat elders in het blad ook nog iets (buiten kolom F).

With Sheets(1)
 .Range("A" & .UsedRange.Rows.Count).Offset(1) = "**vergaderen"
End With

 

[Rob532]

reactie

Ja er staat ook nog wat buiten kolom F. Dus daar moet niet naar gekeken worden.

En hoe zet je een "Subtekst" in kolom B van een nieuwe regel?

Alvast bedankt voor de snelle reactie

 

[Warme bakkertje]

Sub Test()
    Dim varArray(1 To 6, 1 To 1)
    With Sheets(1)
        For i = 1 To 6
            varArray(i, 1) = .Cells(Rows.Count, i).End(xlUp).Offset(1).Row
        Next
        .Range("A" & WorksheetFunction.Max(varArray)) = "**vergaderen"
    End With
End Sub

 

[Rob532]

Geweldig

Nu kan ik weer vooruit.
Alleen mn oplossing voor het vet of italic wegschrijven met andere fontgroote werkt nu niet.
had staan:
ActiveCell.Font.Bold = True
ActiveCell.Font.Size = 12

Moet ik dat op een andere manier combineren met de oplossing van de warme bakker?

Leer graag weer wat bij

 

[HSV]

Sub Test()
    Dim varArray(1 To 6, 1 To 1)
    With Sheets(1)
        For i = 1 To 6
            varArray(i, 1) = .Cells(Rows.Count, i).End(xlUp).Offset(1).Row
        Next
      With .Range("A" & WorksheetFunction.Max(varArray))
        .Value = "**vergaderen"
        .Font.Bold = True
        .Font.Size = 12
      End With
    End With
End Sub

 

[Rob532]

End If zonder blok If

Bedankt voor de hulp maar krijg nu de melding dat hij de If mist. Staat toch duidelijk op de 1e regel. Deze melding is pas gekomen na het toevoegen van `with` voor .Range("A"& enz enz

If CBox_Vloer_Ja = True Then
Worksheets("Calculatie").Select

Dim varArray(1 To 6, 1 To 1)
With Sheets(14)
For i = 1 To 6
varArray(i, 1) = .Cells(Rows.Count, i).End(xlUp).Offset(1).Row
Next
With .Range("A" & WorksheetFunction.Max(varArray))
.Value = "**25 Metaalconstructiewerk"
.Font.Bold = True
.Font.Size = 14
End With


With Sheets(14)
For i = 1 To 6
varArray(i, 1) = .Cells(Rows.Count, i).End(xlUp).Offset(1).Row
Next
With .Range("B" & WorksheetFunction.Max(varArray))
.Value = "25-01 Aluminiumhoeklijn"
.Font.Bold = True
.Font.Italic = True
End With

Sheets("Calculatie").Cells(Rows.Count, 2).End(xlUp).Offset(1).EntireRow.Resize(, 24).Value = Sheets("Vloer artikelen").Columns(2).Find("All. Hoeken", , xlValues, xlWhole).EntireRow.Resize(, 24).Value
Sheets("Calculatie").Range("L" & Sheets("Calculatie").Range("B" & Rows.Count).End(xlUp).Row) = Sheets("Inteligentie").Range("O6")
End If

Wat gaat er dan nog fout??

Bedankt voor het meedenken

 

[Warme bakkertje]

Sub tst()
Dim varArray(1 To 6, 1 To 1)
If CBox_Vloer_Ja Then
    With Sheets("Calculatie")
        For i = 1 To 6
            varArray(i, 1) = .Cells(Rows.Count, i).End(xlUp).Offset(1).Row
        Next
        With .Range("A" & WorksheetFunction.Max(varArray))
            .Value = "**25 Metaalconstructiewerk"
            .Font.Bold = True
            .Font.Size = 14
        End With
    
        For i = 1 To 6
            varArray(i, 1) = .Cells(Rows.Count, i).End(xlUp).Offset(1).Row
        Next
        With .Range("B" & WorksheetFunction.Max(varArray))
            .Value = "25-01 Aluminiumhoeklijn"
            .Font.Bold = True
            .Font.Italic = True
        End With
        .Cells(Rows.Count, 2).End(xlUp).Offset(1).Resize(, 24).Value = Sheets("Vloer artikelen").Columns(2).Find("All. Hoeken", , xlValues, xlWhole).Resize(, 24).Value
        .Range("L" & .Range("B" & Rows.Count).End(xlUp).Row) = Sheets("Inteligentie").Range("O6")
    End With
End If
End Sub

Ik veronderstel dat Sheets(14) hetzelfde is als Sheets("Calculatie") ?

 

[Rob532]

dank is groot

Dit is de oplossing die ik zocht. Nogmaals bedankt.