Lijst in excel samenstellen met totalen

[bartvt78]

wow, ik wist niet dat je ChatGPT hiervoor kan gebruiken. Weeral wat wijzer geworden. Maar ChatGPT zegt zelf dat het een complexe formule is, dat zegt al genoeg zeker. Hopelijk ziet jverkerk dit bericht ergens voorbij komen, en kan die wat duidelijkheid scheppen.

 

[AlexCEL]

Dat is best een pittige van jverkerk HSV. Ik heb een iets simpelere gemaakt:

=LET(x;VERT.STAPELEN(JANUARI:DECEMBER!D6:H100);y;INDEX(x;;5);
z;HOR.STAPELEN(KIES.KOLOMMEN(x;1;2;3;4);y&"");
SORTEREN(UNIEK((FILTER(z;INDEX(z;;1)<>0;"")))))

De nullen uit de laatste kolom vervangen door lege waarden maakt de formule wat langer... (daar is variabele z voor).

 

[bartvt78]

Hey AlexCEL, bedankt voor je bijdrage. Die formule is iets simpeler te behappen, Deze zet de inkomsten vanboven gegroepeerd, en de uitgaven eronder, maar doet geen alfabetische sortering op naam. En om het helemaal perfect te hebben zou direct na de inkomsten de uitgaven moeten staan, en de lijnen "selecteer" helemaal onderaan, want dat zijn de "blanco" lijnen. Ik heb jou formule toegepast op mijn voorbeeldfile, in een aparte tab. De oplossing van jverkerk sorteert eerst op inkomsten/uitgaven, en dan de benaming op alfabetische volgorde, voor zover ik het kan zien toch....

 

[HSV]

De formule komt niet van @jverkerk

 

[AlexCEL]

@HSV: aangepast.

 

[HSV]

Je formule doet helaas geen optelling van de bedragen.

 

[AlexCEL]

Dat hoefde ook niet toch? Volgens mij wilde TS een overzicht van zijn periodieke betalingen.

Ik heb een tweede poging gedaan o.b.v. voorbeeld in post #23, waarbij eerste kolom eerst Uitgaven geeft en dan inkomsten, en tweede kolom alfabetisch is gesorteerd.

=LET(x;VERT.STAPELEN(A3:E15);y;INDEX(x;;5);
z;HOR.STAPELEN(KIES.KOLOMMEN(x;1;2;3;4);y&"");
q;FILTER(z;(INDEX(z;;1)<>0)*(INDEX(z;;1)<>"Selecteer");"");
SORTEREN.OP(q;INDEX(q;;1);-1;INDEX(q;;2);1))

Let wel: de functie VERT.STAPELEN is hier NIET nodig omdat je maar 1 tabblad hebt. Ik heb hem wel laten staan omdat je de functie elders gaat gebruiken.

 

[bartvt78]

HSV, ben ik verkeerd met mijn bronvermelding? Was het jou formule? Dan alvast mijn excuses mocht dat zo zijn, en dan kan jij me zeker een volledige uitleg geven over de formule

 

[bartvt78]

Hey AlexCEL, als er een uitgave of inkomsten 2 keer in de lijst staat, moeten de bedragen wel opgeteld worden.

 

[AlexCEL]

Okidoki, ga ik straks nog even verder met de formule

 

[HSV]

Klopt, staat in het bestand van #11.

Wat wil je ervan weten, @jverkerk heeft je al uitgelegd dat je geen samengevoegde cellen moet gebruiken; daar wordt het onnodig ingewikkeld van.
Zorg dat het aantal kommen in elk tabblad hetzelfde zijn.
Begin in elk blad gewoon in cel A1.

 

[jverkerk]

Nee de formule komt niet van mij, wou dat ik het kon maar jammer.
Ik zei alleen dat hij niet werkte met samengestelde cellen.
Alle eer gaat naar de formulespecialisten.

 

[bartvt78]

Ik heb het gezien. Mijn fout voor foutieve bronvermelding. Het was inderdaad @HSV. Ik heb de tab aangepast. Kan jij dan overal een woordje meer uitleg bij de verschillende stappen zetten aub? Ik heb mijn vragen in kolom G gezet. Denk er wel aan dat je het moet uitleggen aan een excel amateur.d

 

[AlexCEL]

Ik heb de formule aangepast voor je voorbeeld in post #1 omdat hier dubbele waarden in voorkomen en in latere niet. Het wordt dan:

=LET(x;VERT.STAPELEN(JANUARI:DECEMBER!D6:H100);y;INDEX(x;;5);
z;HOR.STAPELEN(KIES.KOLOMMEN(x;1;2;3;4);y&"");
q;FILTER(z;(INDEX(z;;1)<>0)*(INDEX(z;;1)<>"Selecteer");"");
r;SORTEREN.OP(q;INDEX(q;;1);-1;INDEX(q;;2);1);
s;GROEPEREN.PER(r;INDEX(r;;4);SOM;0;0;;;1);
KIES.KOLOMMEN(s;1;2;3;6;5))

Begint aardig op de formule van HSV te lijken ....

 

[HSV]

Groeperen is trouwens al gesorteerd (sort_order).

 

[bartvt78]

Ik ga het nakijken in de loop van vandaag. Hartelijk dank voor de bijdrage AlexCEL. Hopelijk kan ik door de bomen het bos zien in de formule.

 

[AlexCEL]

Je kan de laatste formule in de LET ook toekennen aan een letter, en daarna kun je ze 1 voor 1 tonen. Dus eerst x, dan y, dan z etc. op het einde zetten. Dan zie je precies wat elke stap doet.

 

[HSV]

Ik heb de formule aangepast voor je voorbeeld in post #1 omdat hier dubbele waarden in voorkomen en in latere niet. Het wordt dan:

=LET(x;VERT.STAPELEN(JANUARI:DECEMBER!D6:H100);y;INDEX(x;;5);
z;HOR.STAPELEN(KIES.KOLOMMEN(x;1;2;3;4);y&"");
q;FILTER(z;(INDEX(z;;1)<>0)*(INDEX(z;;1)<>"Selecteer");"");
r;SORTEREN.OP(q;INDEX(q;;1);-1;INDEX(q;;2);1);
s;GROEPEREN.PER(r;INDEX(r;;4);SOM;0;0;;;1);
KIES.KOLOMMEN(s;1;2;3;6;5))

Begint aardig op de formule van HSV te lijken ....

Dezelfde formule als in #11, maar dan net als die van jou @AlexCEL zonder kopteksten.

=LET(x;VERT.STAPELEN(JANUARI:DECEMBER!D6:H100);y;FILTER(x;INDEX(x;;1)<>"");KIES.KOLOMMEN(GROEPEREN.PER(KIES.KOLOMMEN(y;1;2;3;5)&"";INDEX(y;;4);SOM;;0);1;2;3;5;4))

Of met kolomkoppen die iets korter is dan mijn vorige.

=LET(x;VERT.STAPELEN(JANUARI:DECEMBER!D5:H100);y;FILTER(x;INDEX(x;;1)<>"");z;UNIEK(KIES.KOLOMMEN(GROEPEREN.PER(KIES.KOLOMMEN(y;1;2;3;5)&"";INDEX(y;;4);SOM;3;0;1);1;2;3;5;4));FILTER(z;INDEX(z;;4)<>0))

 

[bartvt78]

Hartelijk dank voor de bijdragen. Momenteel heb ik even andere prioriteiten, maar ik bekijk de oplossingen in de loop van deze week. Indien nog iets onduidelijk is, laat ik het weten. Prettige week nog iedereen.

 

[bartvt78]

Ik hoop dat de bronvermelding nu correct is in bijgevoegd bestandje. @HSV, op rij 19 zit nog een schoonheidsfoutje in jou formule. Volgende breinbreker is te vinden vanaf rij 37. Momenteel staat alles overal manueel ingevuld. Ik weet niet of dit resultaat kan gemaakt worden met 1 formule of niet. Alles staat in grijsblauw op de verschillende tabbladen. Dank