Macro korter maken.

[Demeter]

Je selecteert ook wel erg!!! Ook selecteer je bladen waarme je niks doet.

bv:

 Sheets("Van Steenbergen").Select
    Range("A1:I45").Select

kan al

 Sheets("Van Steenbergen").Range("A1:I45").Select

worden.

En waarom cel B1 selecteren als je daarn cel A1 op een ander blad selecteert:

    Range("B1").Select
    Sheets("Van der Straeten").Select
    Range("A1").Select

Al het selecteren maakt je code er niet overzichtelijker op.

 

[Wigi]

Pierre moet gewoon van mijn code vertrekken en lichtjes aanpassen.

Ik wil dat zelf ook doen, maar dan moet natuurlijk de juiste info er zijn.

EDIT: had het bestandje niet gezien. Zie volgende post.

 

[Wigi]

Dit doet het voor een willekeurig tabblad. Opmaak wordt geplakt, en vervolgens de cellen als waarden. Andere keuzes zijn ook mogelijk.

Sub Macro2()
    Range("A1:I45").Copy
    With Sheets("AfdrukPagina").Range("V1")
        .PasteSpecial xlPasteFormats
        .PasteSpecial xlPasteValues
    End With
    Application.CutCopyMode = False
End Sub

Waar moeten de andere tabbladen naartoe op AfdrukPagina?

Wigi

 

[Demeter]

Netjes opgelost met de with functie Wigi:thumb: .

Mijn handicap nu is dat ik nog te vaak dezelfde oplossingen probeer te gebruiken voor verschillende problemen. Maar aldoende leert men.

 

[jpvs]

Heb er dit van gemaakt:

Sub AfdrukpaginaMaken()
    Application.ScreenUpdating = False
    Sheets("Van der Straeten").Range("A1:I45").Copy
    With Sheets("AfdrukPagina").Range("B1")
        .PasteSpecial xlPasteFormats
        .PasteSpecial xlPasteValues
    End With
    
    Sheets("Van Raemdonck").Range("A1:I45").Copy
    With Sheets("AfdrukPagina").Range("L1")
        .PasteSpecial xlPasteFormats
        .PasteSpecial xlPasteValues
    End With
    
    Sheets("Schenck").Range("A1:I45").Copy
    With Sheets("AfdrukPagina").Range("V1")
        .PasteSpecial xlPasteFormats
        .PasteSpecial xlPasteValues
    End With
    
    Sheets("Van Steenbergen").Range("A1:I45").Copy
    With Sheets("AfdrukPagina").Range("AF1")
        .PasteSpecial xlPasteFormats
        .PasteSpecial xlPasteValues
    End With
    Application.CutCopyMode = True
End Sub

alleen het laatste blijft geselecteerd?

Pierre

 

[Wigi]

alleen het laatste blijft geselecteerd?

Bekijk eens

Application.GoTo

Waarom maak je trouwens geen lus door de tabbladen?

Wigi

 

[jpvs]

Waarom maak je trouwens geen lus door de tabbladen?

Omdat niet alle tabladen moeten geprint worden.
In totaal zijn er 10 waarvan er 4 voor afdruk.

Pierre

PS: welk code is er om de selectie ongedaan te maken?

 

[Wigi]

PS: welk code is er om de selectie ongedaan te maken?

Iets anders selecteren, bv. een cel op het beginblad.

 

[Wigi]

Omdat niet alle tabladen moeten geprint worden.
In totaal zijn er 10 waarvan er 4 voor afgedruk.

Je kan een lus door de tabbladen maken, en dan checken wat de naam is. Als die overeenkomt met 1 van de 4, dan uitvoeren, anders niet.

 

[jpvs]

Selectie verdwijnd niet met Range("A1").Activate ?



bedoel je dit in verband met een lus ?

Sub Printen()
    For i = 1 To Sheets.Count
        Sheets(i).PageSetup.PrintArea = "$A$1:$I$28"
        ActiveSheet.PrintOut
    Next
End Sub

Pierre

 

[Wigi]

Sub AfdrukpaginaMaken()
    
    Dim w As Worksheet, sAddress As String
    
    sAddress = ""
    Application.ScreenUpdating = False
    
    For Each w In ThisWorkbook.Worksheets
    
        Select Case w.Name
            Case "Van der Straeten": sAddress = "B1"
            Case "Van Raemdonck": sAddress = "L1"
            Case "Schenck": sAddress = "V1"
            Case "Van Steenbergen": sAddress = "AF1"
            Case Else: sAddress = ""
        End Select
        
        If sAddress <> "" Then
            w.Range("A1:I45").Copy
            With Sheets("AfdrukPagina").Range(sAddress)
                .PasteSpecial xlPasteFormats
                .PasteSpecial xlPasteValues
            End With
        End If
    Next
    
    With Application
        .Goto Sheets("Van der Straeten").Range("A1"), True
        .CutCopyMode = True
        .ScreenUpdating = True
    End With
End Sub

Wigi

 

[jpvs]

Wigi,

Zoals gewoonlijk werkt prima, bedankt voor je geduld.

Pierre