macro regel verwijderen met alle datums na einde dit jaar.

[roycke]

Beste,
De volgende macro werkt perfect echter een probleem:
Hij verwijdert alle regels na "vandaag" echter wat we graag willen is alles na "einde dit jaar"
Wat is hiervoor de juiste benaming?

Sub DeleteDatum()
Dim rng As Range, cell As Range, del As Range
Set rng = Intersect(Range("J2:J999999"), ActiveSheet.UsedRange)
For Each cell In rng
If (cell.Value) >= Date Then
If del Is Nothing Then
Set del = cell
Else: Set del = Union(del, cell)
End If
End If
Next cell
On Error Resume Next
del.EntireRow.Delete
End Sub

 

[edmoor]

Zoiets:

Sub DeleteDatum()
    Dim rng As Range, cel As Range, del As Range
    
    Set rng = Intersect(Range("J2:J999999"), ActiveSheet.UsedRange)
    For Each cel In rng
        If IsDate(cel) And cel.Value > DateValue("31-12-" & Year(Date)) Then
            If del Is Nothing Then
                Set del = cel
            Else
                Set del = Union(del, cel)
            End If
        End If
    Next cel
    
    On Error Resume Next
    del.EntireRow.Delete
End Sub

NB:
Vermijdt het gebruik van correct Engelse woorden als naam van een variabele.
- cell gewijzigd in cel

 

[roycke]

Thankx Edmoor!
Werkt prefect, en bedankt voor de correctie.