Met somproduct een gemiddelde uitrekenen

[Lschot]

Hoi allemaal;
In een bestand om mijn gewicht bij te houden, Wil ik het gemiddelde gewicht per week weten.
Met de functie somproduct geef ik aan om welke week het gaat, die dan netjes word opgezocht, maar als ik om het gemiddelde vraag van die week krijg ik de som.
Waarschijnlijk is het bestand zelf duidelijker dan deze beschrijving.
Dank voor jullie hulp.

 

[Roncancio]

Als je Excel 2007 hebt, kan je gebruik maken van Gemiddelde.Als

=GEMIDDELDE.ALS('Gewicht Totaal'!B3:B360;WAARDE(RECHTS(B4;2));'Gewicht Totaal'!C3:C360)

Met vriendelijke groet,


Roncancio

 

[Lschot]

Dit komt heel aardig in de juiste richting;
Als ik het woord "WAARDE" verwijder,

De formule word dan:

=GEMIDDELDE.ALS('Gewicht Totaal'!$B$3:$B$360;(RECHTS($B4;2));'Gewicht Totaal'!$C$3:$C$360)

Geeft hij inderdaad de gemiddelde waarde aan die ik wil weten, maar heb ik in dit geval nog geen gewicht ingevuld achter de datum op tabblad "gewicht totaal" krijg ik de melding te zien dat ik probeer te delen door 0 ( #deel/0! ) is dit er ook uit te krijgen?

Ik gebruik office 2010.

Bedankt voor het meedenken.
Leo

 

[Roncancio]

=ALS(B4="";"";GEMIDDELDE.ALS('Gewicht Totaal'!$B$3:$B$360;(RECHTS($B4;2));'Gewicht Totaal'!$C$3:$C$360))

Met vriendelijke groet,


Roncancio

 

[HSV]

=ALS.FOUT(GEMIDDELDE.ALS('Gewicht Totaal'!$B$3:$B$360;(RECHTS($B4;2));'Gewicht Totaal'!$C$3:$C$360);"")

Als ik het goed heb gelezen.

 

[Thoralf]

Wat dacht je van de volgende matrix-formule:

=ALS(ISFOUT(VERT.ZOEKEN(B4;'Gewicht Totaal'!B$3:B$360;1;ONWAAR));"";SOM((('Gewicht Totaal'!B$3:B$360)=B4)*(ALS(ISGETAL('Gewicht Totaal'!C$3:C$360);'Gewicht Totaal'!C$3:C$360;0)))/(SOM((('Gewicht Totaal'!B$3:B$360)=B4)*1)))

dus inbrengen met CTRL+SHIFT+ENTER

 

[Lschot]

Bedankt allemaal;
Ik heb uiteindelijk gekozen voor de optie van HSV omdat die helemaal doet wat mijn bedoeling is.
Maar ook de andere formules hebben mij weer iets meer inzicht gegeven in excel.
Nogmaals bedankt.
Leo