msgbox bestand bestaat al,

[Ben]

Ik heb het zover dat het bestand wordt opgeslagen als een pdf bestand.
Hoe kan ik hierin een smgbox krijgen als dit bestand al aanwezig is in de directory?
Wil dit niet overschrijven maar gewoon terug naar de factuur om het factuur nummer te wijzigen.
Het factuur nummer staat in cell K13 Range("K13") echter het bestand wordt weggeschreven met twee range,
K13 en D12 Range("D12") bestandsnaam in de directory is dan ( F:\Ben\factuur pdf\ 1000 janssen )
als de factuur 1000 piet dan had ik graag dat de melding toch komt met bestandsnaam bestaat al.
is dit mogelijk?

Sub OpslaanPDF()
If MsgBox("Wil je dit formulier opslaan als PDF bestand?", _
               vbQuestion + vbYesNo + vbDefaultButton2, _
               "Formulier opslaan als PDF bestand") = vbNo Then
        Exit Sub
    End If

    With Sheets("Factuur")
        .ExportAsFixedFormat _
         Type:=xlTypePDF, _
         Filename:="F:\ben\factuur pdf\" & .Range("K13") & " " & .Range("D12")
Application.Goto [D12]
    End With
End Sub

Met een vriendelijke groet; Ben

 

[edmoor]

Zoiets:

Sub OpslaanPDF()
    With Sheets("Factuur")
        Bestand = "F:\ben\factuur pdf\" & .Range("K13") & " " & .Range("D12") & ".pdf"
    End With
    
    If Dir(Bestand) <> "" Then
        MsgBox "Bestand bestaat al", vbCritical
        Exit Sub
    End If
    
    If MsgBox("Wil je dit formulier opslaan als PDF bestand?", _
               vbQuestion + vbYesNo + vbDefaultButton2, _
               "Formulier opslaan als PDF bestand") = vbNo Then
        Exit Sub
    End If
    
    Sheets("Factuur").ExportAsFixedFormat Type:=xlTypePDF, Filename:=Bestand
    Application.Goto [D12]
End Sub

 

[pasan]

met jou goedvinden edmoor
volgens mij wil Ben alleen een check op het factuur nummer

Sub OpslaanPDF()
If MsgBox("Wil je dit formulier opslaan als PDF bestand?", _
               vbQuestion + vbYesNo + vbDefaultButton2, _
               "Formulier opslaan als PDF bestand") = vbNo Then
        Exit Sub
    End If
    
    With Sheets("Factuur")
     FilePath = "F:\ben\factuur pdf\" & .Range("K13")
      If Dir(FilePath & "*") <> "" Then
        MsgBox "Dit factuur nummer " & .Range("K13") & " bestaat al"
       Exit Sub
      End If
      
        .ExportAsFixedFormat _
         Type:=xlTypePDF, _
         Filename:=FilePath & " " & .Range("D12")
        Application.Goto [D12]
      
    End With
End Sub

 

[edmoor]

Mijn toestemming heb je niet nodig

 

[snb]

Sub M_snb()
    With Sheets("Factuur")
        if dir("F:\ben\factuur pdf\" & .Range("K13") & " " & .Range("D12") & ".pdf")<>"" then .range("D12")=.range("D12")+1
        .ExportAsFixedFormat 0, "F:\ben\factuur pdf\" & .Range("K13") & " " & .Range("D12") & ".pdf"
    End With
End sub

NB. Het is een ontwerpfout als het faktuurnummer niet al eerder automatisch een uniek faktuurnummer is.
Dat moet geregeld zijn voordat er überhaupt van opslaan van een bestand sprake is.

 

[Ben]

het werkt.

beiden dankjewel !!!
code van pasan werkt toppie

Groetjes Ben.

 

[Ben]

hoi allemaal

Hallo snb,

Heb de code van je getest, deze werkt niet de fout begint bij regel 3 code

then .range("D12")=.range("D12")+1

ben al tevreden alles werkt en voor jouw ook bedankt.

groetjes Ben

 

[pasan]

je hebt vast het blad beveiligd zodat er geen schrijf bewerking kan plaats vinden in cel ".range("D12")+1"

 

[Ben]

Hoi pasan

Blad was niet beveiligd en de cel is niet geblokkeerd tijdens de beveiliging.
maar toch jij ook bedankt:thumb:

 

[snb]

wat staat er dan in D12 ?

 

[Ben]

Hoi snb

Sorry dat ik zo laat reageer.

In de cel D12 staat de naam van de persoon waarvan de factuur is.
in cel K13 het factuur nummer.
File heeft dan de naam bevoordeeld: 1111 janssen.pdf

met een vriendelijke groet Ben.