Naar een bepaalde cel gaan

[janemmers]

Ik heb onderstaande formule in een macro gebruikt om in het gebied a14:a26 te zoeken naar de waarde die in cel D6 staat. De bedoeling is dat de cursosr in desbetreffende cel (in de range a14:a26 blijft staan. In ondergenoemd voorbeeld was de waarde in cel d6 4.
Als het getal in d6 zich aanpast moet hij vervolgens weer zoeken naar die nieuwe waarde

Wie heeft er een tip

Range("D6").Select
Selection.Copy
Range("A14:A26").Select
Selection.Find(What:="4", After:=ActiveCell, LookIn:=xlFormulas, LookAt _
:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:= _
False, SearchFormat:=False).Activate
End Sub

 

[trucker10]

Probeer het met deze

Sub Find_First()
    Dim FindString As String
    Dim Rng As Range
    FindString = Range("D6").Value
    If Trim(FindString) <> "" Then
        With Sheets("Blad1").Range("A14:A26")
            Set Rng = .Find(What:=FindString, _
                            After:=.Cells(.Cells.Count), _
                            LookIn:=xlValues, _
                            LookAt:=xlWhole, _
                            SearchOrder:=xlByRows, _
                            SearchDirection:=xlNext, _
                            MatchCase:=False)
            If Not Rng Is Nothing Then
                Application.Goto Rng, True
            Else
                MsgBox "Nothing found"
            End If
        End With
    End If
End Sub

 

[Warme bakkertje]

[Blad1!A14:A26].Find([D6], , xlValues, xlWhole).Activate

Deze kan ook

Application.Goto [Blad1!A14:A26].Find([D6], , xlValues, xlWhole), True

 

[janemmers]

Nog een kleine aanpassing.

Het moet niet afgehandeld worden in Blad1 maar in het huidig werkblad
Omdat het in meerdere tabbladen afgehandeld moet worden, graag iets in de trant van activeSheet

 

[trucker10]

Nog een kleine aanpassing.

Het moet niet afgehandeld worden in Blad1 maar in het huidig werkblad
Omdat het in meerdere tabbladen afgehandeld moet worden, graag iets in de trant van activeSheet

Bij deze

Sub Find_First()
    Dim FindString As String
    Dim Rng As Range
    FindString = [D6]
    If Trim(FindString) <> "" Then
        With ActiveSheet.[A14:A26]
            Set Rng = .Find(What:=FindString, _
                            After:=.Cells(.Cells.Count), _
                            LookIn:=xlValues, _
                            LookAt:=xlWhole, _
                            SearchOrder:=xlByRows, _
                            SearchDirection:=xlNext, _
                            MatchCase:=False)
            If Not Rng Is Nothing Then
                Application.Goto Rng, True
            Else
                MsgBox "Nothing found"
            End If
        End With
    End If

Je kan ook dit in de code wisselen

If Not Rng Is Nothing Then
                Application.Goto Rng, False
            Else