Niet lege waarden in een kolom groeperen

[stefano]

Beste,

Uit een tabel in bijlage wil ik aan de hand van formules enkel die waardes overhouden die niet blanco zijn en deze mooi onder elkaar in een tabel invoegen.

ik hoop dat het voorbeeld in bijlage een beetje duidelijkheid schept.

dank alvast,

Stefano

 

[AlexCEL]

Deze voor A14 (let op matrixfunctie, d.w.z. afsluiten met Control+Shift+Enter voor doorvoeren naar beneden)

=ALS.FOUT(INDEX(E:E;KLEINSTE(ALS($E$4:$E$13<>"";RIJ($4:$13));RIJ(A1)));"")

Of, als je Excel 365 gebruikt deze voor A14:

=FILTER(E4:E13;E4:E13<>"";"")

 

[stefano]

Dank je wel! Hier ga ik verder mee aan de slag.

Eerste formule werkt prima, de tweede geeft steeds dezelfde waarde.

dank alvast!

 

[AlexCEL]

Ik begrijp dat je Excel 365 gebruikt? Dan is de FILTER functie toch gemakkelijker in het gebruik lijkt me.
Ik snap de opmerking "geeft steeds dezelfde waarde" niet zo goed. In bijlage heb ik de 2e formules naast elkaar gezet en ze geven dezelfde uitkomsten...

 

[stefano]

Hoi,

ik had de formule fout ingegeven waardoor ik dezelfde waarde ( 1 1 1 1 1) kreeg. De formule werkt prima.

Dank je wel !

(en ja office 365 )

 

[stefano]

Als ik in cel B1 de keuze 'derde' maak dan moet het bereik aangepast worden naar het bereik dat in de tabel onder derde valt. Hoe kan je dat?

Ik ging al aan de slag met vergelijken zodat ik weet dat criterium 'derde' in kolom 3 staat van de tabel, maar dat helpt me niet direct vooruit, althans hoe kan ik daar nu mee verder?

=VERGELIJKEN("derde";E3:I3;)

Kortom: bij selectie uit de mogelijkheden in B1 zou het bereik moeten aangepast worden naar de overeenstemmende kolom.

zie bijlage voor het aangepaste document.

 

[AlexCEL]

Het wordt er niet simpeler op, maar zoiets?

=FILTER(VERSCHUIVING($D$4:$D$13;;VERGELIJKEN(A$13;$E$3:$I$3;0));VERSCHUIVING($D$4:$D$13;;VERGELIJKEN(A$13;$E$3:$I$3;0))<>"";"")

En als je een hele nieuwe Excel 365 (beta-)versie hebt (via Office Insider programma) kan het ook zo:

=LET(bereik;VERSCHUIVING($D$4:$D$13;;VERGELIJKEN(A$13;$E$3:$I$3;0));FILTER(bereik;bereik<>"";""))

 

[stefano]

Holy Moly, dat is geen gewoon formuleke ..... Het het al getest en het werkt super, nu nog proberen zelf in elkaar te knutselen zonder spieken !

dank je wel !

 

[AlexCEL]

Dit is ook nog een optie:

=FILTER(FILTER(E4:I13;E$3:I$3=A13;"");FILTER(E4:I13;E$3:I$3=A13;"")<>"";"")

Of:

=LET(x;FILTER(E4:I13;E$3:I$3=A13;"");FILTER(x;x<>"";""))