o.b.v. geselecteerde cel in een bereik, inhoud andere cel weergeven

[Pander]

Beste helpers,

Is het ook mogelijk als ik in een bepaald bereik een cel aanklik de inhoud van een andere cel wordt weergeven?

In de bijlage zit een voorbeeldje.

Ik wil graag de geel gearceerde cel in het tabblad maandag als volgt laten veranderen:

Selecteer ik een cel in het bereik E15 t/m U15 dan wordt de inhoud van de cel: Naam 1
Selecteer ik een cel in het bereik E16 t/m U15 dan wordt de inhoud van de cel: Naam 2
etc
etc

Zou te gek zijn als dat mogelijk is. Het dan namelijk mogelijk, als er een dag rooster wordt gemaakt om een doorkijk te maken
in de planning van de betreffende medewerker in die week.

Gr,
Pander

Bekijk bijlage rooster.xlsm

 

[edmoor]

Dat kan er eenvoudig in gemaakt worden maar je VBA project is beveiligd.

 

[Pander]

ohoh . Die kan er wel af trouwens met: 123

 

[edmoor]

Zet dit er in de ThisWorkbook sectie bij:

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
    Select Case LCase(Sh.Name)
        Case "maandag", "dinsdag", "woensdag", "donderdag", "vrijdag"
        Case Else:  Exit Sub
    End Select
    
    If Intersect(Target, Range("E15:U45")) Is Nothing Then Exit Sub
    Range("AA2") = Cells(Target.Row, 4)
End Sub

 

[Pander]

Wauw. Dat is bijna jaloersmakend dat je dat zo (snel) kunt bedenken.

Nog een vraagje. Ik heb het tabelletjes zoals dat op het tabblad maandag staat gekopieerd naar de andere tabbladen.
In het tabblad donderdag gaat er iets niet helemaal goed. Vermoedelijk om dat het bereik groter is. (niet van E t/m U maar van E t/m Z)
De geel gearceerde cel die ik daar graag zou willen veranderen is niet AA2, zoals op de andere tabbladen maar AF2.

Hoe zou ik dit het beste kunnen doen.

Gr,
P
Bekijk bijlage rooster.xlsm

 

[edmoor]

Een goede uitleg en dito voorbeeld helpen daar erg bij

Maak er dit van:

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
    Dim Doel As String, Bereik As String
    Select Case LCase(Sh.Name)
        Case "maandag", "dinsdag", "woensdag", "vrijdag":   Bereik = "U": Doel = "AA2"
        Case "donderdag":                                   Bereik = "Z": Doel = "AF2"
        Case Else:  Exit Sub
    End Select
    
    If Intersect(Target, Range("E15:" & Bereik & "45")) Is Nothing Then Exit Sub
    Range(Doel) = Cells(Target.Row, 4)
End Sub

 

[Pander]

Beste edmoor,

Het werkt als een tierelier. Hartelijk dank voor je aangedragen oplossing. Ben er erg blij mee.

Gr,
Pander

 

[edmoor]

Graag gedaan