openen tweede excel bestand op achtergrond middels vba

[ewezel]

beste helpers,

heb via dit forum een stukje code gevonden waarmee een excel document op de achtergrond geopend wordt als niet actief venster.
Deze code werkt perfect , maar blijft de errmsg geven op het einde van de code. Toch is het bestand geopend als ik in de vb editor kijk.
Heeft iemand enig idee waardoor dit kan komen ben al enkele dagen aan het zoeken maar kom er niet uit.

Private Sub Workbook_Open()
    Dim active As String
    Dim wb As Workbook

Application.ScreenUpdating = False
active = ActiveWorkbook.Name

    On Error Resume Next:
    Set wb = Workbooks("Gegevensblad keuringen.xls")
    On Error GoTo 0

If wb Is Nothing Then
    On Error GoTo ErrMsg
    Set wb = Workbooks.Open("C:\keuringen\Gegevensblad keuringen.xls")

    wb.Activate
    ActiveWindow.Visible = False
    Workbooks(active).Activate
Else
    wb.Activate
    ActiveWindow.Visible = False
    Workbooks(active).Activate
End If

Application.ScreenUpdating = True

ErrMsg: MsgBox "Kan het database bestand niet openen"
On Error GoTo 0

 

[leofact]

Dat wordt w.s. verzaakt door een fout bij foutafhandeling.

Private Sub Workbook_Open()
    Dim active As String
    Dim wb As Workbook

Application.ScreenUpdating = False
active = ActiveWorkbook.Name

    On Error Resume Next:
    Set wb = Workbooks("Gegevensblad keuringen.xls")
    On Error GoTo 0

If wb Is Nothing Then
    On Error GoTo ErrMsg
    Set wb = Workbooks.Open("C:\keuringen\Gegevensblad keuringen.xls")

    wb.Activate
    ActiveWindow.Visible = False
    Workbooks(active).Activate
Else
    wb.Activate
    ActiveWindow.Visible = False
    Workbooks(active).Activate
End If

Application.ScreenUpdating = True
[COLOR="#0000FF"]Exit Sub[/COLOR]
ErrMsg: 
MsgBox "Kan het database bestand niet openen"
On Error GoTo 0
[COLOR="#0000FF"]End Sub[/COLOR]

Ik kan ook 123 geen reden bedenken om een het actieve werkbook te activeren, maar dat zal geen fout veroorzaken denk ik.
Mvg Leo

 

[ewezel]

hoi Leo,

ja dat was het probleem hartelijk dank.

mvg erwin

 

[leofact]

Graag gedaan.
Mvg Leo

 

[snb]

De code kan gereduceerd worden tot:

Private Sub Workbook_Open()
    Getobject("C:\keuringen\Gegevensblad keuringen.xls")
End Sub

 

[ewezel]

Hallo Snb,

inderdaad doet hetzelfde hartelijk dank voor uw medewerking.

mvg erwin