Opmerkingen plaatsen

[wacco]

Hallo,

Ik gebruik onderstaande code om een gedeelte van tabblad bereikbaar te maken.
Code werkt, ik kan binnen deze range alles invullen wat ik wil in de vrij gegeven cellen.
Maar loop nu tegen het probleem aan dat ik geen Opmerkingen kan toevoegen aan de vrij gegeven cellen.
Als ik het hele tabblad vrij geef, is het wel mogelijk, maar dat is nu net niet de bedoeling.
Is dit mogelijk , ….en zo ja, hoe dit dan te doen ?

Private Sub CommandButton2_Click()
       
 Dim PW As String
    PW = Blad1.Range("B10")

            If InputBox("Wachtwoord ingeven aub") = PW Then
               Blad2.Unprotect Password:=PW
               Blad2.Range("H17:NI28").Locked = False
               Blad2.Range("C35:NI47").Locked = False
               
             
                    Blad1.Visible = xlSheetVisible
                    Blad3.Visible = xlSheetVisible
               Blad2.Protect Password:=PW
            

            Else
                MsgBox "Foutief wachtwoord!"
            End If
End Sub

Private Sub CommandButton3_Click()

 Dim PW As String
    PW = Blad1.Range("B10")

            Blad2.Unprotect Password:=PW
            Blad2.Range("H17:NI28").Locked = True
            Blad2.Range("C35:NI47").Locked = True
            Blad2.Protect Password:=PW
            
                Blad1.Visible = xlSheetHidden
                Blad3.Visible = xlSheetHidden
            
End Sub

Gr,

 

[HSV]

Bij het beveiligen van het blad moet je de optie 'Objecten' aanvinken.
Of even kijken in de Help van VBA naar de parameters van protect.

 

[wacco]

@HSV,
Dankje voor je reactie, maar de beveiliging wordt erop geplaatst d.m.v. een knop (commandButton_3).
Ook de beveiliging wordt opgeheven d.m.v. een knop (commandButton_2), vervolgens maak ik een range unlocked, en zet op de rest van het blad daarna weer de beveiliging erop.
Nu wil ik Opmerkingen kunnen plaatsen in de range welke unlocked is....en dit lukt niet.
Ook niet bij het toevoegen van

Contents:=True, DrawingObjects:=False, UserInterfaceOnly:=True

.
Ook niet door de te veranderen in true/false.

Kan alles invullen in de cellen welke zijn unlocked, maar het is niet mogelijk om een opmerking te plaatsen.

Als ik van het volledige blad de beveiliging afhaal (zoals jij voorstelt) is dit inderdaad mogelijk, maar dan kan ik ook in cellen waar je normaal niet in hoeft te zijn een opmerking toevoegen, en natuurlijk kan ik alles daarin aanpassen….wat niet de bedoeling is.

Krijg het maar niet voor elkaar, geen idee hoe ik ervoor kan zorgen dat in de range welke is vrijgegeven (unlocked) een opmerking kan worden geplaatst.

Gr,

 

[HSV]

Probeer het eens met zoiets.

Private Sub Worksheet_selectionChange(ByVal Target As Range)
If Not Intersect(Target, Range("a1:a10")) Is Nothing Then
   Unprotect "ww"
 Else
  Protect "ww"
End If
End Sub

 

[wacco]

@HSV
Bedankt,....ga het uitproberen.

Gr,

 

[wacco]

Ben nog verder gaan experimenteren, en met de volgende code is het gelukt.

Private Sub CommandButton2_Click()
       
 Dim PW As String
    PW = Blad1.Range("B10")

            If InputBox("Wachtwoord ingeven aub") = PW Then
               Blad2.Unprotect Password:=PW
               Blad2.Range("H17:NI28").Locked = False
               Blad2.Range("C35:NI47").Locked = False
               
                    Blad1.Visible = xlSheetVisible
                    Blad3.Visible = xlSheetVisible
               Blad2.Protect Password:=PW, DrawingObjects:=False, Contents:=True, Scenarios:=True
            

            Else
                MsgBox "Foutief wachtwoord!"
            End If
End Sub

Dit is bestaande code, maar met onderstaand gedeelte toegevoegd.
Hiermee is het gelukt.

, DrawingObjects:=False, Contents:=True, Scenarios:=True

Gr,


P.S.

Wordt op opgelost gezet