Oude werkbalken

[mulderwme]

Hallo allemaal,

Ik opende per ongeluk een Excel 2000 bestand met macro's.

Daarin had ik toen een commandbar gemaakt, maar verzuimd om die te deleten bij BeforeClose.

In de huidige versie blijft die commandbar nu zichtbaar, ook als het bestand gesloten is.

Ik weet de naam van de commandbar niet meer. Is er een trucje om dat ding toch te sluiten?

Alvast bedankt
Willem

 

[edmoor]

Deze code laat alle commandbars zien. Misschien dat je daarmee terug kan vinden wat je zoekt:

Sub tst()
On Error GoTo Error_Handler
    Dim i           As Long
    Dim sCmdBar     As CommandBar
 
    Cells(1, 2) = "Nummer"
    Cells(1, 3) = "Naam"
    Cells(1, 4) = "Zichtbaar"
    Cells(1, 5) = "Ingebouwd"
    
    For i = 1 To Application.CommandBars.Count
        Set sCmdBar = Application.CommandBars(i)
        Cells(i + 1, 2) = i
        Cells(i + 1, 3) = sCmdBar.Name
        Cells(i + 1, 4) = sCmdBar.Visible
        Cells(i + 1, 5) = sCmdBar.BuiltIn
    Next i
Error_Handler_Exit:
    On Error Resume Next
    Set sCmdBar = Nothing
    Exit Sub
 
Error_Handler:
    MsgBox "The following error has occured." & vbCrLf & vbCrLf & _
           "Error Number: " & Err.Number & vbCrLf & _
           "Error Source: ListCmdBars" & vbCrLf & _
           "Error Description: " & Err.Description, vbCritical, "An Error has Occured!"
    Resume Error_Handler_Exit
End Sub

 

[mulderwme]

Bedankt Edmoor,

Ik heb ze gevonden. Ik herken de namen ook. Perfect!

Bedankt.
Willem