Opgelost PDF Bestand maken kleine wijziging.

[Dokman]

Heb en script die ik al en tijdje gebruikt.
Deze maakt van het Excel sheet en pdf dit werk super.

Sub PDFActiveSheet()
'www.contextures.com
'for Excel 2010 and later
Dim wsA As Worksheet
Dim wbA As Workbook
Dim strTime As String
Dim strName As String
Dim strPath As String
Dim strFile As String
Dim strPathFile As String
Dim myFile As Variant
On Error GoTo errHandler

Set wbA = ActiveWorkbook
Set wsA = Sheets("Meeting")
strTime = Format(Now(), "dd-mm-yyyy")

'get active workbook folder, if saved
strPath = wbA.Path
If strPath = "" Then
  strPath = Application.DefaultFilePath
End If
strPath = strPath & "\Bestanden\"

'replace spaces and periods in sheet name
strName = Replace(wsA.Name, " ", "")
strName = Replace(strName, ".", "_")

'create default name for savng file
strFile = "Test " & strTime & ".pdf"
strPathFile = strPath & strFile

'use can enter name and
' select folder for file
myFile = Application.GetSaveAsFilename _
    (InitialFileName:=strPathFile, _
        FileFilter:="PDF Files (*.pdf), *.pdf", _
        Title:="Select Folder and FileName to save")

'export to PDF if a folder was selected
If myFile <> "False" Then
    wsA.ExportAsFixedFormat Type:=xlTypePDF, _
        Filename:=myFile, _
        Quality:=xlQualityStandard, _
        IncludeDocProperties:=True, _
        IgnorePrintAreas:=False, _
        OpenAfterPublish:=False
    'confirmation message with file info
    MsgBox "PDF-bestand is gemaakt: " _
      & vbCrLf _
      & myFile
End If

exitHandler:
    Exit Sub
errHandler:
    MsgBox "Kan geen PDF-bestand maken"
    Resume exitHandler
End Sub

strFile = "Test " & strTime & ".pdf"
Hij slaat het bestand op als TEST 22-5-2024.pdf, maar wil graag dat bij
test en waarde komt te staan die ik invul in de sheet op E5.

 

[snb]

Dit is een Nederlandstalig forum.

 

[OctaFish]

Gelukkig heb ik Google Translate .

    strFile = "Test " & [E5] & ".pdf"

 

[Dokman]

@snb Jammer van je opmerking. Gelukkig zijn we niet allemaal zoals jou. Want dan zou iedereen zo intelligent zijn als jij. En dan zou jij overbodig worden.

@OctaFish Bedankt heb en kleine verandering gedaan. Krijg alleen geen spatie tussen wat er in E5 staat en de datum als ik en pdf ga maken.

 strFile = [E5] & strTime & ".pdf"

 

[Mde]

strFile = [E5] & " " & strTime & ".pdf"

zo?

 

[Dokman]

Dank jullie wel.