Plaatjes via koppeling worden niet allemaal weergegeven

[Gruytkluit]

Ik probeer in Access plaatjes in een rapport weer te geven middels de methode die beschreven staat in artikel 285820 (MS site)

Door eerdere hulp van Octafish lukte het om deze procedure aan de praat te krijgen.

Als ik nu een groot rapport wil draaien worden aan het einde van het rapport diverse afbeeldingen niet meer weergegeven. De afbeeldingen staan wel gewoon in de map. Een nog groter rapport wordt na 60 pagina's afgebroken en niet gemaakt.

Soms krijg ik een geheugen melding, maar vaak ook niet.

Heeft iemand een idee waaraan dit kan liggen?

Alvast bedankt

 

[OctaFish]

Wat is een groot rapport? En hoe laad je de afbeeldingen in?

 

[Gruytkluit]

Het is een rapport met ongeveer 400 records. Per record worden 2 plaatjes geladen.

Om de plaatjes te laden gebruik ik onderstaande module:

Option Compare Database
Option Explicit

Public Function DisplayImage(ctlImageControl As Control, strImagePath As Variant) As String
On Error GoTo Err_DisplayImage

Dim strResult As String
Dim strDatabasePath As String
Dim intSlashLocation As Integer

With ctlImageControl
    If IsNull(strImagePath) Then
        .Visible = False
        strResult = "No image name specified."
    Else
        If InStr(1, strImagePath, "\") = 0 Then
            ' Path is relative
            strDatabasePath = CurrentProject.FullName
            intSlashLocation = InStrRev(strDatabasePath, "\", Len(strDatabasePath))
            strDatabasePath = Left(strDatabasePath, intSlashLocation)
            strImagePath = strDatabasePath & strImagePath
        End If
        .Visible = True
        .Picture = strImagePath
        strResult = "Image found and displayed."
    End If
End With
    
Exit_DisplayImage:
    DisplayImage = strResult
    Exit Function

Err_DisplayImage:
    Select Case Err.Number
        Case 2220       ' Can't find the picture.
            ctlImageControl.Visible = False
            strResult = "Can't find image in the specified name."
            Resume Exit_DisplayImage:
        Case Else       ' Some other error.
            MsgBox Err.Number & " " & Err.Description
            strResult = "An error occurred displaying image."
            Resume Exit_DisplayImage:
    End Select
End Function

Die roep ik vervolgens aan in het detail gedeelte van het rapport met onderstaande code.

Option Compare Database
Option Explicit
Private Sub Details_Format(Cancel As Integer, FormatCount As Integer)
Me!Imagenote = DisplayImage(Me!Frame, Me!locatie)
Me!imagenote2 = DisplayImage(Me!frame2, Me!locatie2)
End Sub

De afbeeldingen zijn ongeveer 200 tot 300 kB groot