Preport preview

[JEPEDEWE]

Hallo,

Ik geeft bij het openen van een Rapport het command dit eerst in preview te tonen.
maar, dan duikelt dat venster onder alle openstaande vensters. (die ik als acDialog open)
Ik kan er pas naartoe als ik eerst alle vensters sluit en dan klopt de referentie naar een van die forms op het rapport niet meer natuurlijk..
Enig idee hoe ik die preview bovenop de andere vernsters kan krijgen?
Merci
JP

 

[OctaFish]

De formulieren niet als acDialog openen, bijvoorbeeld....
Beetje flauwe oplossing, maar wel waar. Wat ik zelf meestal doe: alle formulieren Hidden maken, en bij het sluiten van het rapport weer zichtbaar.

 

[JEPEDEWE]

Vind die Dialog wel echt nodig, anders "wandelen" ze van de ene form naar de andere en dat is zeker de bedoeling niet
Dat Hidden gedoe is misschien wel een oplossing...
Hoe is het commando?
JP

 

[OctaFish]

In een module zet je deze functies:

Option Compare Database
Option Explicit
Dim intx As Integer
Dim intCount As Integer

Function fIsLoaded(ByVal strFormName As String) As Integer
    'Returns a 0 if form is not open or a -1 if Open
    If SysCmd(acSysCmdGetObjectState, acForm, strFormName) <> 0 Then
        If Forms(strFormName).CurrentView <> 0 Then
            fIsLoaded = True
        End If
    End If
End Function

Function HideForms()
    
    intCount = Forms.Count - 1
    For intx = intCount To 0 Step -1
         If fIsLoaded(Forms(intx).Name) Then
             Application.Forms(intx).Form.Visible = False
         End If
    Next

End Function

Function ShowForms()
    
    intCount = Forms.Count - 1
    For intx = intCount To 0 Step -1
         If fIsLoaded(Forms(intx).Name) Then
             Application.Forms(intx).Form.Visible = True
         End If
    Next

End Function

Bij het openen van het rapport gebruik je deze code:

HideForms
DoCmd.OpenReport "Rapport", acViewPreview

En bij het sluiten van het rapport:

Private Sub Report_Close()
    ShowForms
End Sub

 

[JEPEDEWE]

Gewoon top man!!! dat' is't...
Dikke merci
JP